将对象添加到 bitMapData

Question

截至目前。我有3个对象。一张位图充当我的画布。和2个位图数据。一个是我的缓冲区，另一个是我的图块。我正在为游戏创建平铺效果。我想获取我的tile：BitMapData，并将其转换为自定义对象。原因是我希望每个图块都是交互式的。这样我就可以点击每一个。是否可以将代表图块的 bitMapData 转换为具有属性和方法的自定义对象。有点像电影剪辑。并将其绘制到我的缓冲区中？我可以创建一个扩展 bitMapData 的新类吗？或者我是否必须摆脱缓冲区并将图块对象直接绘制到位图中？

换句话说，将 Sprite 或图块放入 BitMapData 对象甚至 Bitmap 中的最佳方式是什么。

Answer 1

首先，BitmapData 和 Bitmap 不可互换。它们是两种截然不同的东西。 BitmapData 类包含位图像素数据，并允许您操作该像素数据，例如绘制它、​​更改特定像素的颜色等。无法直接显示 BitmapData，即将其添加到显示列表中。

另一方面，Bitmap 类是一个 DisplayObject，如 MovieClips 和 Sprites，您可以将其添加到显示列表中。它的唯一目的是在显示列表中渲染 BitmapData。事实上，它甚至不是交互式的，因此您无法直接检测 Bitmap 实例上的点击。

关于您的问题：如果您有一个包含图块精灵的位图数据，并且您想在另一个位图数据中绘制该图块，则可以使用 BitmapData.draw() 方法或 BitmapData.copyPixels() 方法。后者是可用于任何 BitmapData 的最快方法之一，因此我强烈推荐它。

根据您的特定应用程序，在位图中绘制所有内容可能根本没有好处。听起来好像您希望能够检测所有图块上的单击事件，这让我认为您可能会受益于将它们作为单独的 DisplayObjects（例如 Sprites）。

如果需要，您可以创建一个扩展 Sprite 的 Tile 类，并使用位图填充绘制 BitmapData。这样，您就可以拥有所需的任何属性，并且还可以检测图块实例上的鼠标事件。

package
{
  /* ... imports ... */

  public class Tile extends Sprite 
  {
    private var _solid : Boolean;

    public function Tile(bmp : BitmapData, solid : Boolean)
    {
      this.graphics.beginBitmapFill(bmp, null, false, true);
      this.graphics.drawRect(0, 0, bmp.width, bmp.height);

      _solid = solid;
    }

    /**
     * Sample custom property. Could be used to define whether a tile
     * is solid, e.g. the player cannot pass it.
    */
    public function get isSolid() : Boolean
    {
      return _solid;
    }
  }
}

可以简单地为游戏中的每个图块实例化此类，并传入应在图块中绘制的位图数据。您还可以侦听此类图块实例上的事件。

var tile : Tile;

tile = new Tile(myBitmapData, false);
tile.x = 200;
tile.y = 200;
tile.addEventListener(MouseEvent.CLICK, handleTileClick);

addChild(tile);

这样，您根本不必使用 Bitmap 类来渲染图块。它们可以直接添加到显示列表中。

Answer 2

我想出了一个更好的解决方案，当您想要选择图块的某些部分而不影响精灵本身的位置时，

theMatrix.translate(30,0);
this.graphics.beginBitmapFill(tileImage,theMatrix);
//this.graphics.drawRect(0, 0,tWidth ,tHeight );
this.graphics.endFill();

您的权利，将绘制矩形保留在 0, 0。使用 Matrix.Translate，允许您移动图块的哪个部分的位置您想要的图块，而不影响精灵位置本身。