鼠标松开事件无法正常工作

Question

谁能帮我解决这个问题吗？ 附件是 fla，其中包含我正在为一个项目编写的部分代码。

在鼠标的帮助下，您可以在图像上画一个圆圈，但由于某些原因，鼠标向上事件不起作用。当事件侦听器附加到舞台时它工作正常，但当它附加到影片剪辑时则不起作用。

另外，我如何限制只在矩形影片剪辑内部绘制圆。

这是代码

    const CANVAS:Sprite = new Sprite();
var _dragging:Boolean = false;
var _corner:Point;
var _corner2:Point;

menFront.addEventListener(MouseEvent.MOUSE_DOWN, setAnchor);
menFront.addEventListener(MouseEvent.MOUSE_UP, completeRect);


function setAnchor(e:MouseEvent):void{
    trace("mouse down");
    if(!_dragging){
        CANVAS.graphics.clear(); 

        _corner = new Point(e.stageX, e.stageY);
        _dragging = true;
        menFront.addEventListener(MouseEvent.MOUSE_MOVE, liveDrag);
    }
}

function completeRect(e:MouseEvent):void{
    trace("mouse up");
    if(_dragging){    
        _dragging = false;
        menFront.removeEventListener(MouseEvent.MOUSE_MOVE, liveDrag);
        CANVAS.graphics.lineStyle(0, 0, 0);
        CANVAS.graphics.beginFill(0x222222,.5)

        _corner2 = new Point(e.stageX, e.stageY);
        trace(Point.distance(_corner,_corner2).toFixed(2));
        CANVAS.graphics.drawCircle(_corner.x, _corner.y, Point.distance(_corner,_corner2));
        addChild(CANVAS); 
    }
}

function liveDrag(e:MouseEvent):void{
    CANVAS.graphics.clear(); 
    CANVAS.graphics.lineStyle(0, 0x999999);

    _corner2 = new Point(e.stageX, e.stageY);
    //trace(Point.distance(_corner,_corner2).toFixed(2));
    CANVAS.graphics.drawCircle(_corner.x, _corner.y, Point.distance(_corner,_corner2));
    addChild(CANVAS); 
}

Answer 1

如果您将 MouseEvent.MOUSE_UP 添加到您正在拖动的对象，则只有当 MOUSE_UP 发生时该项目位于鼠标下方时，该事件才会触发，但由于您正在使用以下命令更新该项目MOUSE_MOVE，这是 MOUSE_UP 发生和 MOUSE_MOVE 发生之间的竞争条件。

为了避免此类问题，您需要保证在实时更新周期内每当 MOUSE_UP 触发时您都会收到 MOUSE_UP。为此，请在需要时将事件侦听器添加到舞台，如下所示：

menFront.addEventListener(MouseEvent.MOUSE_DOWN, setAnchor);

function setAnchor(event:MouseEvent):void
{
    stage.addEventListener(MouseEvent.MOUSE_UP, completeRect);
    // your other functionality
}

function completeRect(event:MouseEvent):void
{
    stage.removeEventListener(MouseEvent.MOUSE_UP, completeRect);
    // your other functionality
}

这样，如果您单击其他地方，您的completeRect就不会被无意中调用。

希望这有帮助