如何使可能挂起的分叉进程超时？

Question

我正在编写一个 Perl 脚本，它将写入一些输入并将这些输入发送到外部程序。该程序挂起的可能性虽小但非零，我想将其超时：

my $pid = fork;
if ($pid > 0){
    eval{
        local $SIG{ALRM} = sub { die "TIMEOUT!"};
        alarm $num_secs_to_timeout;
        waitpid($pid, 0);
        alarm 0;
    };
}
elsif ($pid == 0){
    exec('echo blahblah | program_of_interest');
    exit(0);
}

就目前情况而言，在 $num_secs_to_timeout 之后，program_of_interest 仍然存在。我尝试在 $SIG{ALRM} 的匿名子例程中杀死它，如下所示：

local $SIG{ALRM} = sub{kill 9, $pid; die "TIMEOUT!"}

但这不会执行任何操作。 program_of_interest 仍然存在。我该如何杀死这个进程？

Answer 1

我能够通过终止进程组成功终止我的 exec()ed 进程，如问题 在 perl 中，当使用 open 创建 child 时杀死 child 及其子组件。我修改了我的代码如下：

my $pid = fork;
if ($pid > 0){
    eval{
        local $SIG{ALRM} = sub {kill 9, -$PID; die "TIMEOUT!"};
        alarm $num_secs_to_timeout;
        waitpid($pid, 0);
        alarm 0;
    };
}
elsif ($pid == 0){
    setpgrp(0,0);
    exec('echo blahblah | program_of_interest');
    exit(0);
}

超时后，program_of_interest被成功杀死。

Answer 2

上面的代码（由 strictrude27 编写）并没有开箱即用，因为 -$PID 是大写的。
（顺便说一句：还有： http://www.gnu.org /software/coreutils/manual/html_node/timeout-invocation.html）

这是一个测试示例：

#!/usr/bin/perl
use strict;
use warnings;
use File::Basename;

my $prg = basename $0;
my $num_secs_sleep = 2;
my $num_secs_to_timeout = 1;
my $orig_program = "sleep $num_secs_sleep; echo \"Look ma, survived!\"";
my $program = $orig_program;
my $expect = "";

if (@ARGV){
  if($ARGV[0] eq "test"){
    test();
    exit 0;
  } elsif (@ARGV == 1) {
    $num_secs_to_timeout = $ARGV[0];
  } elsif (@ARGV == 2) {
    $program = $ARGV[0];
    $num_secs_to_timeout = $ARGV[1];
  } else {
    die "Usage: $prg [ \"test\" | [program] seconds ] "
  }
}

if($orig_program eq $program) {
  if(@ARGV < 2) {
    $expect = $num_secs_to_timeout > $num_secs_sleep ?
      "(we expected to survive.)" : "(we expected to TIME OUT!)";
  }
  print STDERR "sleeping: $num_secs_sleep seconds$/";
}

print STDERR <<END;
  timeout after: $num_secs_to_timeout seconds,
  running program: '$program'
END

if($orig_program eq $program) {
  print STDERR "$expect$/";
}

exit Timed::timed($program, $num_secs_to_timeout);

sub test {
  eval "use Test::More qw(no_plan);";
  my $stdout;
  close STDOUT;
  open STDOUT, '>', \$stdout or die "Can't open STDOUT: $!";
  Timed::timed("sleep 1", 3);
  is($stdout, undef);
  Timed::timed("sleep 2", 1);
  is($stdout, "TIME OUT!$/");
}

################################################################################
package Timed;
use strict;
use warnings;

sub timed {
  my $retval;
  my ($program, $num_secs_to_timeout) = @_;
  my $pid = fork;
  if ($pid > 0){ # parent process
    eval{
      local $SIG{ALRM} = 
        sub {kill 9, -$pid; print STDOUT "TIME OUT!$/"; $retval = 124;};
      alarm $num_secs_to_timeout;
      waitpid($pid, 0);
      alarm 0;
    };
    return defined($retval) ? $retval : $?>>8;
  }
  elsif ($pid == 0){ # child process
    setpgrp(0,0);
    exec($program);
  } else { # forking not successful
  }
}

Answer 3

嗯，经过一些小的修改，你的代码对我有用 - 我认为这些修改是你自己为了使代码成为通用示例而进行的更改。

因此，这给我留下了两个想法：

1. 您在创建示例代码时解决了问题 - 尝试创建一个实际运行的小示例（我必须将“program_of_interest”和 $num_secs_to_timeout 更改为实际值来测试它）。确保样品有同样的问题。
2. 这与您正在运行的program_of_interest有关 - 据我所知，您无法掩盖kill 9，但也许正在发生一些事情。您是否尝试过使用非常简单的脚本来测试您的代码？我为我的测试创建了一个 while (1) { print "hi\n";睡觉1； }
3. 其他东西。

祝你好运...

Answer 4

可以忽略 SIGKILL 的唯一方法是进程陷入不可中断的系统调用中。检查挂起进程的状态（使用ps aux），如果状态为D，则该进程无法被杀死。

您可能还想通过输出某些内容来检查该函数是否正在被调用。