通过 TortoiseSVN 提交时，如何强制我们的开发人员输入注释？

Question

我经常看到大量的提交，但没有引用票据的注释......所以我最终返回并手动检查差异。不一定是坏事，但如果有笔记就更好了。有什么想法吗？

Answer 1

不是 TortoiseSVN，而是 Subversion 本身 - 服务器上的设置。您可以设置一个预提交挂钩来强制执行提交注释。如果您想更进一步，还有一些预提交挂钩可以验证是否存在对 Jira 等问题跟踪系统的引用。

Answer 2

您可以定义一个预提交挂钩脚本，该脚本会拒绝所有带有空或太短日志消息的提交。

这是帖子 关于如何去做。

Answer 3

您需要使用预提交挂钩，它是一种服务器设置，我为 VisualSVN 编写了一个挂钩，它基本上是一个批处理文件 - 类似的脚本可用于非基于 Windows 的 SVN 服务器。

@echo off
::
:: Stops commits that have empty log messages.
::
@echo off
setlocal

rem Subversion sends through the path to the repository and transaction id
set REPOS=%1
set TXN=%2

rem check for an empty log message
call "C:\program files\visualsvn server\bin\svnlook" log %REPOS% -t %TXN% | findstr . > nul
if %errorlevel% gtr 0 (goto err) else exit 0

:err
echo. 1>&2
echo Your commit has been blocked because you didn't give any log message 1>&2
echo Please write a log message describing the purpose of your changes and 1>&2
echo then try committing again. -- Thank you 1>&2
exit 1

Answer 4

当然可以，但是您将如何强制执行非胡言乱语、有意义且上下文相关的提交消息？

当你发现蹩脚/空洞的提交时，最好直接打你不负责任的同事。或者相当于“拳击”的口头表达。只要确保他们感觉不好，这是应得的。

Answer 5

我使用了预提交挂钩脚本来确保提交注释始终引用问题跟踪系统中的问题号。例如，诸如此类的评论

fixes frobulator when the moon is full (bug 1234)

将被接受，因为它包含错误号。即使采用这种安排，您仍然必须相信开发人员会插入有意义的注释和错误号。

Answer 6

我们的预提交钩子脚本（Windows 批处理）：

@echo off & setlocal ENABLEEXTENSIONS

set SVNLOOK="E:\Subversion\Program\Subversion 1.5.0\bin\svnlook.exe"

set REPOS=%1%
set TXN=%2%
set LOGFILE=%REPOS%\hooks\log-%TXN%.txt
set GREP=E:\UnxUtils\usr\local\wbin\grep.exe

%SVNLOOK% log -t "%TXN%" "%REPOS%" >%LOGFILE%

set "first="
for /f "delims=" %%a in ('more ^< "%LOGFILE%"') do (
  if not defined first set first=%%a
)

del %LOGFILE%

if not defined first ( echo "Please supply a commit comment" >&2 & exit 1 )





REM Check for invalid windows characters in the path
echo Checking >%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "\" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find ":" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "*" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "?" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find """" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^>" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^<" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^|" >>%LOGFILE%

set "first="
for /f "delims=" %%a in ('more +1 ^< "%LOGFILE%"') do (
  if not defined first set first=%%a
)

del %LOGFILE%

if defined first ( echo "Please do not use filename characters which are invalid in  windows. - Found %first%" >&2 & exit 1 )






REM Tagblock - prevent changes to tag directories
echo Checking >%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | %GREP% "^U.*\/tags\/.*" | %GREP% -v -f "%REPOS%\conf\tag-block-exceptions.txt" >>%LOGFILE%

set "first="
for /f "delims=" %%a in ('more +1 ^< "%LOGFILE%"') do (
  if not defined first set first=%%a
)

del %LOGFILE%


if defined first ( 
    echo "%first% -- Error: Modifications to tag directories are blocked. To allow these modifications add the path to %REPOS%\conf\tag-block-exceptions.txt" >&2 
    exit 1 )

Answer 7

您可以很容易地强制提交评论，但最终您将得到一百万个表示“调试”或“测试”的提交。

如果您的开发人员看不到添加提交消息的价值，则强制他们输入某些内容不会改变这一点。

更糟糕的是，当 Eclipse 用户集成了 SVN/CVS 以便记住他们最后的提交消息时，他们最终会提交一个与上一个任务/项目的消息完全不相关的文件。

Answer 8

TortoiseSVN 是一个客户端，您可能需要 在颠覆服务器上强制评论。
或者你可以告诉他们评论他们的提交。