如何从 Perl 将输入传送到 Java 命令？

Question

我需要通过 Java 程序运行一个字符串，然后检索输出。 Java 程序通过标准输入接受字符串。以下内容有效：

my $output = `echo $string | java -jar java_program.jar`;

有一个问题：$string 可以是任何东西。对于解决这个问题有什么好的想法吗？

Answer 1

我建议您查看 IPC::Run3模块。它使用非常简单的界面，并允许获取STDERR和STDOUT。这是一个小例子：

use IPC::Run3;
## store command output here
my ($cmd_out, $cmd_err);
my $cmd_input = "put your input string here";
run3([ 'java', '-jar', 'java_program.jar'], \$cmd_input, \$cmd_out, \$cmd_err);
print "command output [$cmd_out] error [$cmd_err]\n";

请参阅 IPC::Run3 与其他模块的比较。

Answer 2

如果您可以使用 CPAN 模块（我假设大多数人都可以），请查看 Ivan 关于使用 的回答 IPC::Run3。它应该处理你需要的一切。

如果您无法使用模块，请按照以下方法以简单的方式执行操作。

您可以使用管道来进行输入，它将避免所有这些命令行引用问题：

open PIPE, "| java -jar java_program.jar";
print PIPE "$string";
close(PIPE);

不过，看起来您实际上需要命令的输出。您可以使用类似 IPC::Open2 （往返于 java 进程），但是尝试同时处理两个管道可能会让自己陷入死锁。

您可以通过将 java 输出到文件，然后从该文件读取来避免这种情况：

open PIPE, "| java -jar java_program.jar > output.txt";
print PIPE "$string";
close(PIPE);

open OUTPUT, "output.txt";
while (my $line = <OUTPUT>) {
    # do something with $line
}
close(OUTPUT);

另一种选择是以相反的方式执行操作。将 $string 放入临时文件中，然后将其用作 java 的输入：

open INPUT, "input.txt";
print INPUT "$string";
close(INPUT); 

open OUTPUT, "java -jar java_program.jar < input.txt |";
while (my $line = <OUTPUT>) {
    # do something with the output
}
close(OUTPUT);

请注意，这不是处理临时文件的最佳方法；为了简单起见，我刚刚使用了 output.txt 和 input.txt。查看 File::Temp 文档 各种更干净的方法来更干净地创建临时文件。

Answer 3

您是否研究过 IPC::Run ？

您可能正在寻找与此类似的语法：

use IPC::Run qw( run );
my $input = $string;
my ($out, $err);
run ["java -jar java_program.jar"], \$input, \$out, \$err;

Answer 4

创建一个管道，就像您的 shell 一样。

这是我们可怕的字符串：

my $str = "foo * ~ bar \0 baz *";

我们将向后构建管道，因此首先我们收集 Java 程序的输出：

my $pid1 = open my $fh1, "-|";
die "$0: fork: $!" unless defined $pid1;

if ($pid1) {
  # grab output from Java program
  while (<$fh1>) {
    chomp;
    my @c = unpack "C*" => $_;
    print "$_\n  => @c\n";
  }
}

注意 Perl 的 参数perldoc.perl.org/functions/open.html" rel="nofollow noreferrer">open 运算符。

如果您在命令 '-' 上打开管道，即，可以是 '|-' 或 '-| ' 具有 2 个参数（或 1 个参数）形式的 open()，然后隐式 fork 完成，并且返回值 >open 是父进程中子进程的 pid，而 0 是子进程中的 ...... 文件句柄对于父进程表现正常，但对该文件句柄的 i/o 是通过管道传输的/到子进程的 STDOUT/STDIN。

unpack 用于查看从管道读取的数据的内容。

在您的程序中，您需要运行 Java 程序，但下面的代码使用了合理的传真：

else {
  my $pid2 = open my $fh2, "-|";
  die "$0: fork: $!" unless defined $pid2;

  if ($pid2) {
    $| = 1;
    open STDIN, "<&=" . fileno($fh2)
      or die "$0: dup: $!";

    # exec "java", "-jar", "java_program.jar";

    # simulate Java program
    exec "perl", "-pe", q(
      BEGIN { $" = "][" }
      my @a = split " ", scalar reverse $_;
      $_ = "[@a]\n";
    );
    die "$0: exec failed";
  }

最后，不起眼的孙子只是打印可怕的字符串（到达 Java 程序的标准输入）并退出。将 $| 设置为 true 值会刷新当前选定的文件句柄并将其置于无缓冲模式。

  else {
    print $str;
    $| = 1;
    exit 0;
  }
}

其输出：

$ ./try
[*][zab][][rab][~][*][oof]
  => 91 42 93 91 122 97 98 93 91 0 93 91 114 97 98 93 91 126 93 91 42 93 91 111 111 102 93

请注意，NUL 在行程中幸存下来。

Answer 5

内置 IPC::Open2 模块提供了无需外部文件即可处理双向管道的功能。