Delphi：类中的记录

Question

以下情况：

type
  TRec = record
    Member : Integer;
  end; 

  TMyClass = class
  private
    FRec : TRec;
  public
    property Rec : TRec read FRec write FRec;
  end;

以下内容不起作用（无法分配左侧），这没关系，因为 TRec 是值类型：

MyClass.Rec.Member := 0;

在 D2007 中，尽管以下内容确实有效：

with MyClass.Rec do
  Member := 0;

不幸的是，它不起作用在 D2010 中（我认为它在 D2009 中也不起作用）。第一个问题：这是为什么？是故意改变的吗？或者这只是其他变化的副作用？ D2007 解决方法只是一个“bug”吗？

第二个问题：您对以下解决方法有何看法？使用安全吗？

with PRec (@MyClass.Rec)^ do
  Member := 0;

我在这里讨论的是现有代码，因此要使其工作而必须进行的更改应该是最小的。

谢谢！

Answer 1

不

MyClass.Rec.Member := 0;

编译是设计使然。事实上，两个“with”结构的编译（AFAICT）仅仅是一个疏忽。因此，两者都不“可以安全使用”。

两个安全的解决方案是：

1. 将 MyClass.Rec 分配给您操作的临时记录，然后分配回 MyClass.Rec。
2. 将 TMyClass.Rec.Member 公开为其自身的属性。

Answer 2

在像这样的情况下，类的记录需要“直接操作”，我经常采用以下方法：

PMyRec = ^TMyRec;
TMyRec = record
  MyNum : integer
end;

TMyObject = class( TObject )
PRIVATE
  FMyRec : TMyRec;
  function GetMyRec : PMyRec;
PUBLIC
  property MyRec : PMyRec << note the 'P'
    read GetMyRec;
end;

function TMyObject.GetMyRec : PMyRec; << note the 'P'
begin
  Result := @FMyRec;
end;

这样做的好处是，您可以利用 Delphi 自动取消引用来使可读代码访问每个记录元素，即：

MyObject .MyRec.MyNum := 123;

我不记得了，但也许WITH适用于这种方法——我尽量不使用它！
布莱恩

Answer 3

不能直接赋值的原因是这里。
至于WITH，它仍然可以在D2009中工作，我希望它也可以在D2010中工作（我现在无法测试）。
更安全的方法是直接公开记录属性，如 Allen 在上述 SO 帖子：

property RecField: Integer read FRec.A write FRec.A;

Answer 4

记录是值，它们并不意味着是实体。

它们甚至具有按副本分配的语义！这就是为什么您无法就地更改属性值的原因。因为它会违反 FRec 的值类型语义，并破坏依赖它不可变或至少是安全副本的代码。

他们的问题是，为什么你需要一个值（你的 TRec）来表现得像一个对象/实体？

无论如何，如果这就是您使用它的目的，那么将“TRec”作为一个类不是更合适吗？

我的观点是，当你开始使用超出其意图的语言功能时，你很容易发现自己处于必须一路与你的工具作斗争的境地。

Answer 5

它被更改的原因是它是一个编译器错误。它编译的事实并不能保证它会起作用。
一旦将 Getter 添加到属性中，它就会失败。

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm2 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    FPoint: TPoint;
    function GetPoint: TPoint;
    procedure SetPoint(const Value: TPoint);
    { Private declarations }
  public
    { Public declarations }
    property Point : TPoint read GetPoint write SetPoint;
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.Button1Click(Sender: TObject);
begin
  with Point do
  begin
    X := 10;
    showmessage(IntToStr(x)); // 10
  end;

  with Point do
    showmessage(IntToStr(x)); // 0

  showmessage(IntToStr(point.x)); // 0
end;

function TForm2.GetPoint: TPoint;
begin
  Result := FPoint;
end;

procedure TForm2.SetPoint(const Value: TPoint);
begin
  FPoint := Value;
end;

end.

您的代码会突然中断，您会首先责怪 Delphi/Borland 允许这样做。

如果您无法直接分配属性，请不要使用 hack 来分配它 - 有一天它会反噬。

使用 Brian 的建议返回一个指针，但删除 With - 你可以轻松执行 Point.X := 10;

Answer 6

另一个解决方案是使用辅助函数：

procedure SetValue(i: Integer; const Value: Integer);
begin
  i := Value;
end;
SetValue(MyClass.Rec.Member, 10);

尽管它仍然不安全（请参阅 Barry Kelly 对 Getter/Setter 的评论）

/编辑：下面是最丑陋的黑客（也可能是最不安全的），但它太有趣了，我不得不发布它：

type
  TRec = record
    Member : Integer;
    Member2 : Integer;
  end;

  TMyClass = class
  private
    FRec : TRec;
    function GetRecByPointer(Index: Integer): Integer;
    procedure SetRecByPointer(Index: Integer; const Value: Integer);
  public
    property Rec : TRec read FRec write FRec;
    property RecByPointer[Index: Integer] : Integer read GetRecByPointer write SetRecByPointer;
  end;

function TMyClass.GetRecByPointer(Index: Integer): Integer;
begin
  Result := PInteger(Integer(@FRec) + Index * sizeof(PInteger))^;
end;

procedure TMyClass.SetRecByPointer(Index: Integer; const Value: Integer);
begin
  PInteger(Integer(@FRec) + Index * sizeof(PInteger))^ := Value;
end;

它假设记录的每个成员都是（P）整数大小，如果不是，AV 将崩溃。

  MyClass.RecByPointer[0] := 10;  // Set Member
  MyClass.RecByPointer[1] := 11;  // Set Member2

您甚至可以将偏移量硬编码为常量并直接通过偏移量进行访问

const
  Member = 0;
  Member2 = Member + sizeof(Integer);  // use type of previous member

  MyClass.RecByPointer[Member] := 10;

    function TMyClass.GetRecByPointer(Index: Integer): Integer;
    begin
      Result := PInteger(Integer(@FRec) + Index)^;
    end;

    procedure TMyClass.SetRecByPointer(Index: Integer; const Value: Integer);
    begin
      PInteger(Integer(@FRec) + Index)^ := Value;
    end;

MyClass.RecByPointer[Member1] := 20;