XSL：如何测试当前节点是否是另一个节点的后代

Question

我对 XSLT 还很陌生，但目前需要将它用于 CMS。我已经提出了一个问题，但我将尝试描述我的问题，但不会涉及太多有关底层 CMS 的信息。如果您需要更多上下文来帮助我，我可以将其添加进去。

所以我想做的就是测试 xml 的节点是否是特定节点的后代。

<xsl:if test="$currentNode::IsADescendantOf($someNode)">
Write this out.
</xsl:if>

有人有什么想法吗？

提前致谢 ：）

Answer 1

您应该使用联合操作和节点集大小比较：

<xsl:if test="count($someNode|$currentNode/ancestor::*) = count($currentNode/ancestor::*)">
Write this out.
</xsl:if>

如果 $someNode 是 $currentNode 的祖先，则 $someNode|$currentNode/ancestor::* 将返回相同的值节点集为 $currentNode/ancestor::* （节点集没有任何双倍隆）。

如果不是，则由于并集，第一个节点集将比第二个节点集多一个节点。

Answer 2

一个可移植的（XPath 1.0 和 2.0）解决方案是：

<xsl:if test="
  $currentNode/ancestor::*[generate-id() = generate-id($someNode)]
">
Write this out.
</xsl:if>

沿着祖先轴向上走并检查其中的每个元素。如果（且仅当）祖先之一的唯一 ID 与 $someNode 的唯一 ID 匹配时，生成的节点集不为空。

非空节点集的计算结果为 true，因此满足条件。

测试 - 查找所有 是 的后代：

<xml>
  <foo>
    <bar>
      <baz>Test 1</baz>
    </bar>
  </foo>
  <baz>Test 2</baz>
</xml>

并且

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:template match="/">
    <xsl:variable name="someNode" select="//foo[1]" />

    <!-- test each <baz> node if it has <foo> as a parent -->
    <xsl:for-each select="//baz">
      <xsl:if test="
        ancestor::*[generate-id() = generate-id($someNode)]
      ">
        <xsl:copy-of select="." />
      </xsl:if>

    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

结果为

<baz>Test 1</baz>

注意，如果您指的是实际当前节点，就像我在 for-each 中所做的那样，不需要单独的 $currentNode 变量。默认情况下，所有 XPath 都是相对于当前节点的。

一种变体是自上而下的方式。但效率较低（可能低几个数量级）：

<xsl:if test="
  $someNode[//*[generate-id() = generate-id($currentNode)]]
">
Write this out.
</xsl:if>

Answer 3

答案很简单，

您所要做的就是：

<xsl:if test="count(ancestor::somenode)>0">

    ...然后添加其余的

逻辑是，如果该节点是某个节点的后代，那么它将拥有一个或多个该节点。

Answer 4

查看 XSL/XPath 参考中的“祖先”轴

<xsl:if test="ancestor::*[. is $somenode]">

编辑：我正在与您一起学习。看看这是否有效（我希望我的 XSL 调试器在此系统上可用:-)

Answer 5

后代检查

最好的方法是使用后代::* 轴。

如果您有一段如下所示的 XML，并且想要匹配第一个 节点的后代 节点。

XML

<root>
<!-- check for descendants of the following alpha node-->
<alpha>
  <!-- match the following node-->
  <a>...</a>
  <b>...</b>
  <c>...</c>
</alpha>
<alpha>
  <a>...</a>
  <c>...</c>
</alpha>
</root>

XSLT

<xsl:if test="/root/alpha[1]/descendant::a[. is current()]">

祖先检查

这可能在大多数情况下都有效。

<xsl:if test="ancestor::*[name() = $node]">

。

<xsl:variable name="node" select="name(//alpha)"/>

如果您有多个节点要比较并且需要确保它是节点匹配而不是名称匹配，则您可以使用generate-id()

<xsl:variable name="node" select="generate-id(//alpha[3])"/>
<xsl:if test="ancestor::*[generate-id(.) = $node]">

IMO 比较运算符在比较祖先时不能使用，因为它需要叶节点，而叶节点没有后代。

但我建议使用后代::* 轴，因为它更具可读性和灵活性。