AS3：覆盖子类中的受保护变量

Question

我这里停电了我以为我理解了这些原则，但我似乎无法再让它发挥作用了。我想让DeleteButton继承一个通用的Button类。此删除按钮应更改受保护的填充值并具有静态标签。这就是我所拥有的：

public class Button
{
    private var _labelText:String;

    protected var _paddingX:Number = 10;
    protected var _paddingY:Number = 5;

    public function Button( labelText:String ):void
    {
        _labelText = labelText;
    }
}

public class DeleteButton extends Button
{
    public function DeleteButton():void
    {
        _paddingX = 5;
        _paddingY = 2;

        super( 'x' );
    }
}

现在，我认为继承类中更改的 _paddingX 和 _paddingY 值会冒泡到超类。但他们没有。 DeleteButton 仍然是使用超类的默认值构造的。我不知道该怎么做了。我在这里缺少什么？

提前致谢。

编辑：

我想我将 AS3 的实现与 PHP 的实现混合在一起了。 PHP 中的这个“等效”示例是完全合法的：

class Button
{

    protected $_paddingX = 10;
    protected $_paddingY = 5;

    public function __construct( $label = '' )
    {
        var_dump( $label . ':' );
        var_dump( $this->_paddingX );
        var_dump( $this->_paddingY );
        echo '<br>';
    }
}

class DeleteButton extends Button
{
    public function __construct()
    {
        $this->_paddingX = 5;
        $this->_paddingY = 2;

        parent::__construct( 'x' );
    }
}

$button = new Button( 'browse' );
$deleteButton = new DeleteButton();

// this outputs:
string(7) "browse:" int(10) int(5) 
string(2) "x:" int(5) int(2)

Answer 1

当您调用 super() 函数时，您还初始化了所有超类变量。因此，在您的示例中，当您调用 ..

_paddingX = 5;
_paddingY = 2;

.. 在调用 super() 之前，您实际上是在该函数内创建任意值。所以你说得对，只是这些变量在调用 super() 函数之前不存在。

public class Button
{
    private var _labelText:String;

    protected var _paddingX:Number;
    protected var _paddingY:Number;

    public function Button( labelText:String, paddingX:Number=10, paddingY:Number=5 ):void
    {
        _paddingX = paddingX;
        _paddingY = paddingY;

        _labelText = labelText;
    }
    public function traceVars():void {
        trace(_labelText);
        trace(_paddingX);
        trace(_paddingY);
    }
}

public class DeleteButton extends Button
{
    public function DeleteButton():void
    {
        super( 'x', 5, 2 );

    }
}

相反，您可以保留默认值（如 10 和 5），但可以根据需要更改它们。现在，如果您在主时间线上调用它，它应该适合您。

var but:DeleteButton = new DeleteButton();
but.traceVars();

希望这能解释它:)

乔治

Answer 2

我认为在设置 _paddingX 和 _paddingY 之前调用 super('x') 可能会有所不同：

 public function DeleteButton():void
    {
        super( 'x' );

        _paddingX = 5;
        _paddingY = 2;
    }

Answer 3

您可以做的是重写 getter：

public class Button
{
    private var _labelText:String;

    protected var _paddingX:Number = 10;
    protected var _paddingY:Number = 5;

    public function Button( labelText:String ):void
    {
        _labelText = labelText;
    }

    protected function get paddingX():Number
    {
        return _paddingX;
    }
    // get paddingY ommited for brevity
}

public class DeleteButton extends Button
{
    public function DeleteButton():void
    {
        super( 'x' );
    }

    override protected function get paddingX():Number
    {
        return 42;
    }
}

父 Button 构造函数现在将使用子 DeleteButton 类中重写的 getter。

您还可以将 _paddingX/Y 设置为私有以将它们隐藏在实现中，并在 DeleteButton 中添加新的 _paddingX/Y。然而，这似乎是一种肮脏的做法，因为 DeleteButton 中的属性不是由 API 强制执行的。