Flex Alert 控件：激活“默认”警报输入/空格键上的按钮

Question

无论我尝试什么，我似乎都无法触发 Flex 3.4 应用程序中警报控件中“默认”按钮的单击事件。

Alert.show(
    'Are you sure you want to delete the selected link?',
    'Confirm Delete',
    Alert.YES | Alert.CANCEL,
    null, 
    confirmDelete, 
    null, 
    Alert.YES
);

在上面的代码示例中，最后一个参数：Alert.YES 指定“默认”选项（来自第三个参数中的按位列表）是“是”按钮。理论上，根据我设计 Windows 应用程序的经验，“默认按钮”意味着按 Enter 键（或有时按空格键）会触发该按钮的单击事件。

如果很重要，则相关警报是模态的。

我可以看到该按钮的样式是默认的：与“取消”按钮相比，或者在将 null 作为最后一个参数传递时与自身相比，它会出现一点光环或额外的边框。

然而，按 Enter 和 Space 键似乎没有任何影响。我是否做错了什么，或者错过了让此功能发挥作用的一些关键步骤？

---

2010-02-17 更新：

基于我对 @rhtx 的回答的第二条评论：

好吧，终于开始尝试这个了。由于 Alert 类使用了大量静态方法，因此我基本上只是将 Alert 和 AlertForm 类复制到我的项目中（并修复了包含的一些相对路径），而我最终得到的是一个更丑陋的警报框，它可以工作（或不能工作） ，取决于您的观点）与普通警报类相同。然而，我确实意识到，如果您按 TAB 键，它将聚焦警报按钮，此时按 Escape/Enter 键将达到预期的效果...那么我如何消除按 TAB 键的需要？

我又尝试了一些事情，但一无所获。

我在打开警报后尝试伪造 TAB 按键（同时具有 KEY_DOWN 和 KEY_UP 事件类型）：

var a:Alert = Alert.show(msg, title, Alert.YES | Alert.CANCEL, null, fnCb);
var tabEvent:KeyboardEvent = new KeyboardEvent(
    KeyboardEvent.KEY_DOWN,
    true,
    false, 
    0,
    Keyboard.TAB
);
a.dispatchEvent(tabEvent);

我还发现 这篇博文 并尝试这样做来集中 alertForm：

var a:Alert = Alert.show(msg, title, Alert.YES | Alert.CANCEL, null, fnCb);
a.mx_internal::alertForm.setFocus();

这些都没有引发错误，但也没有产生所需的结果。

Answer 1

我将通过扩展 Alert 类来包含侦听 Enter 和 Space 键的 keyUp 事件的功能来解决此问题。

在您的子类的 createChildren 方法中：

override public function createChildren():void
{
    super.createChildren();
    this.addEventListener(KeyboardEvent.KEY_UP, keyUpListener);
    this.stage.addEventListener(KeyboardEvent.KEY_UP, keyUpListener);
}

private function keyUpListener(e:KeyboardEvent):void
{
    if(e.keyCode == Keyboard.ENTER || e.keyCode == Keyboard.SPACE)
    {
        //Trigger the Alert.YES functionality...
    }
}

我今天早上的设置遇到了一些问题，无法进入 Alert 类来提供有关如何“触发 Alert.YES 功能”的信息，但我会尝试稍后再发布一些相关内容。希望这一点有帮助。

另外 - 我不是 100% 同意 - 但我认为您需要在删除警报弹出窗口时手动删除事件侦听器。

Aaand...您可能不需要这两个听众。现在无法测试来确定。

更新： -----------------

经过更多的观察，也许最好的方法是扩展 AlertForm 类（它管理警报的按钮），然后扩展Alert 类使用扩展的 AlertForm 类。

AlertForm 类有一个 keyDownHandler 方法，其定义如下：

override protected function keyDownHandler(event:KeyboardEvent):void
{
    var buttonFlags:uint = Alert(parent).buttonFlags;

    if (event.keyCode == Keyboard.ESCAPE)
    {
        if ((buttonFlags & Alert.CANCEL) || !(buttonFlags & Alert.NO))
            removeAlert("CANCEL");
        else if (buttonFlags & Alert.NO)
            removeAlert("NO");
    }
}

您可以看到它正在设置“关闭”行为以响应按 Escape 键。您可以根据上面“keyUpListener”函数中的代码添加一些逻辑，以调用 AlertForm 的removeAlert 方法，并为“是”按钮传入适当的字符串值。

作为参考，removeAlert 方法如下所示：

private function removeAlert(buttonPressed:String):void
{
    var alert:Alert = Alert(parent);

    alert.visible = false;

    var closeEvent:CloseEvent = new CloseEvent(CloseEvent.CLOSE);
    if (buttonPressed == "YES")
        closeEvent.detail = Alert.YES;
    else if (buttonPressed == "NO")
        closeEvent.detail = Alert.NO;
    else if (buttonPressed == "OK")
        closeEvent.detail = Alert.OK;
    else if (buttonPressed == "CANCEL")
        closeEvent.detail = Alert.CANCEL;
    alert.dispatchEvent(closeEvent);

    mx.managers.PopUpManager.removePopUp(alert);

}

Answer 2

我遇到了类似的情况。让我摆脱困境的是：

(1) 在 Alert.show() 中定义默认按钮，(2) 使用 callLater()，以及 (3) 设置手动将焦点放在默认按钮上。

例如，使用 Alert.CANCEL 作为预期的默认按钮（如果需要，可以更改为 Alert.YES）：

var a:Alert = Alert.show(msg, title, Alert.YES | Alert.CANCEL, null, fnCb, null, Alert.CANCEL);
callLater(setAlertButtonFocus,[a]);
...
private function setAlertButtonFocus(a:Alert):void {
    a.mx_internal::alertForm.mx_internal::defaultButton.setFocus();
}

这使得 Escape 和 Enter 键的作用就像用户用鼠标单击了默认按钮一样。