如何编写与 Set 一起使用的 Rebol 代码块（以编程方式）？

Question

我想这样做：

>> SET [a b] reduce [(ask "a: ") (ask "b: ")]
a: 1
b: 2
== ["1" "2"]
>>

以编程方式：

args: [a b]
block: copy []
foreach arg args [
  append block to-word "("
  append block 'ask
  append block rejoin [arg ": "]
  append block to-word ")"
]
set args reduce block

但我收到此错误：

>>     foreach arg args [
[          append block to-word "("
[          append block 'ask
[          append block rejoin [arg ": "]
[          append block to-word ")"
[        ]
== [( ask "a: " ) ( ask "b: " )]
>>    set args reduce block
** Script Error: ( has no value
** Near: ( ask "a: " ) (
>>

Answer 1

您发现括号不是 word!。它们内置于 Rebol 中，解析器确保它们与您匹配——就像 block! 一样。

这是一件好事，否则系统周围都会有处理 ()))() 不匹配的代码。你已经从那种痛苦中被拯救出来了！但如果您愿意，您可以用自己的方言重新发明这种痛苦，并使用 BEGIN 和 END 之类的单词，而不是利用永远有用的 paren!。 :P

这是对您的代码的简约补丁：

args: [a b]
block: copy []
foreach arg args [
   p: to-paren []
   append/only block p
   append p 'ask
   append p rejoin [arg ": "]
]
set args reduce block

请注意，您不能编写 copy ()。一般来说，在 do 方言中，括号的使用比块要复杂一些——它们具有双重优先权！解释器认为 copy () 意味着您正在尝试将要复制其结果的表达式括起来。 :(

你可以通过将东西构建为块，然后仅在最后一刻转换它们来为自己省去一些麻烦：

>> to-paren [ask "a: "]
== (ask "a: ")

PS 我不想通过指出括号实际上并不是必需的来分散你对问题的注意力：

>> SET [a b] reduce [ask "a: " ask "b: "]

但是好消息是，如果您愿意在这种情况下让括号服务于“更高的目的”，那么总是有 compose

args: [a b]
block: copy []
foreach arg args [
    append block compose [ask (rejoin [arg ": "])]
]
set args reduce block

组合就像使用“模板方言”，只会减少包含的表达式这是通过示例创建代码的好方法，但如果您生成的代码已经使用括号作为优先级，那么肯定会遇到麻烦！仍然...表明您的方言可以使用括号任何目的，就像它们可以赋予文字意义一样。