如何在不使用 eval 的情况下动态包含 Perl 模块？

Question

我需要动态包含 Perl 模块，但如果可能的话，由于工作编码标准，我希望远离 eval。这是可行的：

$module = "My::module";
eval("use $module;");

但如果可能的话，我需要一种无需 eval 即可完成此操作的方法。所有 google 搜索都会导致 eval 方法，但不会以任何其他方式进行。

是否可以在没有eval的情况下做到这一点？

Answer 1

使用 require 在运行时加载模块。将其包装在块（而不是字符串）eval 中通常是一个好主意，以防模块无法加载。

eval {
    require My::Module;
    My::Module->import();
    1;
} or do {
   my $error = $@;
   # Module load failed. You could recover, try loading
   # an alternate module, die with $error...
   # whatever's appropriate
};

使用 eval {...} 或 do {...} 语法并复制 $@ 的原因是 $@是一个全局变量，可以由许多不同的事物设置。您希望尽可能以原子方式获取该值，以避免其他因素将其设置为不同值的竞争条件。

如果您直到运行时才知道模块的名称，则必须手动在模块名称 (My::Module) 和文件名 (My/Module.pm) 之间进行转换：

my $module = 'My::Module';

eval {
    (my $file = $module) =~ s|::|/|g;
    require $file . '.pm';
    $module->import();
    1;
} or do {
    my $error = $@;
    # ...
};

Answer 2

如何使用核心模块 Module::Load

以您的示例：

use Module::Load;
my $module = "My::module";
load $module;

“Module::Load - 两者的运行时要求模块和文件”

“加载使您无需知道您是否需要文件或模块。”

如果失败，它将因类似“无法在 @INC 中定位 xxx（@INC 包含：...”）而终止。

Answer 3

好吧，总是有 require 如

require 'My/Module.pm';
My::Module->import();

注意，你会失去任何东西您可能会从编译时而不是运行时调用 import 中获得效果。

编辑：此方法和 eval 方法之间的权衡是：eval 允许您使用正常的模块语法，并在模块名称无效（而不是仅仅找不到）时给出更明确的错误。 OTOH，eval 方式（可能）更容易受到任意代码注入的影响。

Answer 4

不，没有eval是不可能的，因为require()需要裸字模块名称，如perldoc -f require。然而，这并不是对 eval 的恶意使用，因为它不允许注入任意代码（当然，假设您可以控制您需要的文件的内容）。

编辑： 代码已修改如下，但为了完整性，我保留第一个版本。

我使用 我曾经使用这个小糖模块在运行时进行动态加载：

package MyApp::Util::RequireClass;

use strict;
use warnings;

use Exporter 'import'; # gives you Exporter's import() method directly
our @EXPORT_OK = qw(requireClass);

# Usage: requireClass(moduleName);
# does not do imports (wrong scope) -- you should do this after calling me: $class->import(@imports);
sub requireClass
{
    my ($class) = @_;
    eval "require $class" or do { die "Ack, can't load $class: $@" };
}

1;

PS。我盯着这个定义（我很久以前写的），我正在考虑添加这个：
$class->export_to_level(1, undef, @imports);...它应该工作，但未经测试。

编辑：现在是版本 2，无需评估就好多了（感谢 ysth）：:)

package MyApp::Util::RequireClass;

use strict;
use warnings;

use Exporter 'import'; # gives you Exporter's import() method directly
our @EXPORT_OK = qw(requireClass);

# Usage: requireClass(moduleName);
# does not do imports (wrong scope) -- you should do this after calling me: $class->import(@imports);
sub requireClass
{
    my ($class) = @_;

    (my $file = $class) =~ s|::|/|g;
    $file .= '.pm';
    require $file;  # will die if there was an error
}

1;

Answer 5

CPAN 上的 Class::MOP 有一个 load_class 方法：
http://metacpan.org/pod/Class::MOP

Answer 6

我喜欢做这样的事情：

require Win32::Console::ANSI if ( $^O eq "MSWin32" );