VB6 中的 CheckTokenMembership

Question

我很难将这个 C++ 代码转换为 VB6 代码。我在网上搜索过，但没有找到任何东西。 PInvoke.net 仅引用了 VB.NET 代码。以下是来自 MSDN 的代码：

BOOL IsUserAdmin(VOID)
/*++ 
Routine Description: This routine returns TRUE if the caller's
process is a member of the Administrators local group. Caller is NOT
expected to be impersonating anyone and is expected to be able to
open its own process and process token. 
Arguments: None. 
Return Value: 
   TRUE - Caller has Administrators local group. 
   FALSE - Caller does not have Administrators local group. --
*/
{
    BOOL b;
    SID_IDENTIFIER_AUTHORITY NtAuthority = SECURITY_NT_AUTHORITY;
    PSID AdministratorsGroup; 
    b = AllocateAndInitializeSid(
        &NtAuthority,
        2,
        SECURITY_BUILTIN_DOMAIN_RID,
        DOMAIN_ALIAS_RID_ADMINS,
        0, 0, 0, 0, 0, 0,
        &AdministratorsGroup); 
    if(b) 
    {
        if (!CheckTokenMembership( NULL, AdministratorsGroup, &b)) 
        {
             b = FALSE;
        } 
        FreeSid(AdministratorsGroup); 
    }
    
    return(b);
}

如果有人能帮忙将其转换为 VB6 代码，那就太好了。

谢谢！

编辑：
我原本打算使用该功能，但 MSDN 说：

此函数是 CheckTokenMembership 的包装器。建议直接调用该函数来确定管理员组状态，而不是调用 IsUserAnAdmin。

Answer 1

试试这个

Option Explicit

Private Const SECURITY_BUILTIN_DOMAIN_RID       As Long = &H20
Private Const DOMAIN_ALIAS_RID_ADMINS           As Long = &H220

Private Declare Function AllocateAndInitializeSid Lib "advapi32.dll" (pIdentifierAuthority As Any, ByVal nSubAuthorityCount As Byte, ByVal nSubAuthority0 As Long, ByVal nSubAuthority1 As Long, ByVal nSubAuthority2 As Long, ByVal nSubAuthority3 As Long, ByVal nSubAuthority4 As Long, ByVal nSubAuthority5 As Long, ByVal nSubAuthority6 As Long, ByVal nSubAuthority7 As Long, lpPSid As Long) As Long
Private Declare Sub FreeSid Lib "advapi32.dll" (ByVal pSid As Long)
Private Declare Function CheckTokenMembership Lib "advapi32.dll" (ByVal hToken As Long, ByVal pSidToCheck As Long, pbIsMember As Long) As Long

Private Type SID_IDENTIFIER_AUTHORITY
    Value(0 To 5)            As Byte
End Type

Private Function pvIsAdmin() As Boolean
    Dim uAuthNt         As SID_IDENTIFIER_AUTHORITY
    Dim pSidAdmins      As Long
    Dim lResult         As Long

    uAuthNt.Value(5) = 5
    If AllocateAndInitializeSid(uAuthNt, 2, SECURITY_BUILTIN_DOMAIN_RID, DOMAIN_ALIAS_RID_ADMINS, 0, 0, 0, 0, 0, 0, pSidAdmins) <> 0 Then
        If CheckTokenMembership(0, pSidAdmins, lResult) <> 0 Then
            pvIsAdmin = (lResult <> 0)
        End If
        Call FreeSid(pSidAdmins)
    End If
End Function

Answer 2

您已发布 CheckTokenMembership 的 MSDN 示例代码 - 它使用 CheckTokenMembership 来确定用户是否是管理员。

在 VB6 中，使用 IsUserAnAdmin 更容易，它是 CheckTokenMembership 的包装器。 MSDN 文档 说 IsUserAnAdmin 已弃用，但它比 CheckTokenMembership 更容易调用。

Private Declare Function IsUserAnAdmin Lib "Shell32" Alias "#680" () As Integer
If IsUserAnAdmin() = 0 Then 
  MsgBox "Not admin" 
Else 
  MsgBox "Admin" 
End If

Answer 3

除非有原因需要转换代码，否则请使用 API

Private Declare Function IsUserAdmin Lib "Shell32" Alias "#680" () As Boolean

Private Sub Form_Load()
   If IsUserAdmin Then MsgBox "User is Admin"
End Sub