如何实现TFrame的OnResizeEnd事件？

Question

应用程序的中间是一个框架。调整大小后，我需要重新排列此面板上的控件（在调整大小事件中执行此操作太忙）。 如果可以在所有调整大小之后执行一次，则更有用。但如何呢？

感谢您的帮助

Answer 1

诀窍是挂钩父表单的消息处理（概念验证代码，使用 Delphi 2009 进行测试，错误和极端情况处理需要更多工作）：

type
  TFrame2 = class(TFrame)
  strict private
    fOnEnterSizeMove: TNotifyEvent;
    fOnExitSizeMove: TNotifyEvent;
    fSavedWndProc: TWndMethod;
    procedure DoEnterSizeMove;
    procedure DoExitSizeMove;
    procedure ParentWindowProc(var AMessage: TMessage);
  protected
    procedure CreateWnd; override;
    procedure DestroyWnd; override;
  published
    property OnEnterSizeMove: TNotifyEvent read fOnEnterSizeMove
      write fOnEnterSizeMove;
    property OnExitSizeMove: TNotifyEvent read fOnExitSizeMove
      write fOnExitSizeMove;
  end;

{ TFrame2 }

procedure TFrame2.CreateWnd;
var
  ParentForm: TCustomForm;
begin
  inherited;
  ParentForm := GetParentForm(Self);
  if ParentForm <> nil then begin
    fSavedWndProc := ParentForm.WindowProc;
    ParentForm.WindowProc := ParentWindowProc;
  end;
end;

procedure TFrame2.DestroyWnd;
var
  ParentForm: TCustomForm;
begin
  ParentForm := GetParentForm(Self);
  if ParentForm <> nil then
    ParentForm.WindowProc := fSavedWndProc;
  inherited;
end;

procedure TFrame2.DoEnterSizeMove;
begin
  if Assigned(fOnEnterSizeMove) then
    fOnEnterSizeMove(Self);
end;

procedure TFrame2.DoExitSizeMove;
begin
  if Assigned(fOnExitSizeMove) then
    fOnExitSizeMove(Self);
end;

procedure TFrame2.ParentWindowProc(var AMessage: TMessage);
begin
  fSavedWndProc(AMessage);
  if AMessage.Msg = WM_ENTERSIZEMOVE then
    DoEnterSizeMove;
  if AMessage.Msg = WM_EXITSIZEMOVE then
    DoExitSizeMove;
end;

请注意，每当用于移动/调整大小的辅助消息循环时都会发送消息已开始或已离开 - 无法区分移动和调整大小。如果您需要确保仅捕获大小，则应该在处理程序中比较框架的新旧大小。

Answer 2

您可以尝试以下实现。

- 挂钩所有者窗体的 Resize 事件，在框架内处理它，并触发父 OnResize 可能具有的任何事件处理程序。

type
  TFrame2 = class(TFrame)
    Label1: TLabel;
    procedure FrameClick(Sender: TObject);
  private
    { Private declarations }
    FOnResize: TNotifyEvent;

    procedure OnFrameResize(Sender: TObject);
  public
    { Public declarations }
    // custom Frame constructor
    constructor Create(AOwner: TComponent); override;
  end;

implementation

{$R *.dfm}

{ TFrame2 }

constructor TFrame2.Create(AOwner: TComponent);
begin
  inherited;

  FOnResize := TForm(AOwner).OnResize;
  TForm(AOwner).OnResize := OnFrameResize;
end;

procedure TFrame2.OnFrameResize(Sender: TObject);
begin
  Label1.Caption := 'resize fired';
  if @FOnResize <> nil then
    FOnResize(Parent);
end;

Answer 3

我认为这可以通过调整大小事件停止（重置时间）并启动一个带有短超时（如 0.3 秒）的计时器来完成。然后，帧的大小调整将在其余调整大小之后不久完成。

Answer 4

1）用特殊接口标记您的框架。像： INeedLayoutAfterResize :)

2）编写 TForm 的自定义后代，它将捕获调整大小事件（如前面的答案所示），然后查找其子项，如果某个子项被标记，则重新布局其内容。

实际上我使用这种方法来保存和恢复控件状态。
我的习惯是迭代其子控件并查找 Tag 属性（如果它小于零），将其状态写入 ini 文件。