如何查找前面没有另一个特定单词的单词？

Question

我可以使用哪个正则表达式来查找所有 bar 前面没有字符串 foo 的字符串？两者之间有空格也是非法的。

所以正则表达式应该匹配以下字符串，

foo is bar
hello bar

但不是这些

foobar
foo     bar

我尝试使用以下字符串

(?!<foo)bar

，它完成了消除 foobar 的工作，但我需要处理空格，当然

(?!<foo)\s*bar

匹配所有琴弦。

谢谢！

Answer 1

最好使用编程语言的其他功能，而不是过于费力地寻找正则表达式模式。

您正在查找 $s =~ /bar/ 而不是 $s =~ /foo\s*bar/ 为 true 的字符串。

下面脚本的其余部分仅用于测试。

#!/usr/bin/perl

use strict; use warnings;

my %strings = (
    'foo is bar'  => 1,
    'hello bar'   => 1,
    'foobar'      => 0,
    'foo     bar' => 0,
    'barbar'      => 1,
    'bar foo'     => 1,
    'foo foo'     => 0,
);

my @accept = grep { $strings{$_} } keys %strings;
my @reject = grep { not $strings{$_} } keys %strings;

for my $s ( @accept ) {
    if ( $s =~ /bar/ and not $s =~ /foo\s*bar/ ) {
        print "Good: $s\n";
    }
    else {
        print "Bad : $s\n";
    }
}

for my $s ( @reject ) {
    if ( $s =~ /bar/ and not $s =~ /foo\s*bar/ ) {
        print "Bad : $s\n";
    }
    else {
        print "Good: $s\n";
    }
}

输出：

E:\srv\unur> j
Good: bar foo
Good: hello bar
Good: foo is bar
Good: barbar
Good: foo foo
Good: foo     bar
Good: foobar

Answer 2

给定一些测试用例，

my @match = (
  "foo is bar",
  "hello bar",
);

my @reject = (
  "foobar",
  "foo     bar",
);

您当然可以通过将一种模式的结果提供给另一种模式来完成：

my @control = grep !/foo\s*bar/, grep /bar/ => @match, @reject;

我们也可以用一个模式来完成：

my $nofoo = qr/
  (      [^f] |
    f  (?! o) |
    fo (?! o  \s* bar)
  )*
/x;

my $pattern = qr/^ $nofoo bar /x;

但不要相信我的话。

for (@match) {
  print +(/$pattern/ ? "PASS" : "FAIL"), ": $_\n";
}

for (@reject) {
  print +(/$pattern/ ? "FAIL" : "PASS"), ": $_\n";
}

Answer 3

  (?!<foo)\s*bar

这将匹配空白

Answer 4

php：

!preg_match(/foo\s*bar/,$string) && preg_match(/bar/,$string)

perl：

$string !~ /foo\s*bar/ && $string =~ /bar/

Answer 5

从早期答案中获取信息，包装为 perl 单行代码，并使正则表达式不区分大小写。

Windows：

perl -lne "print $_ if $_ !~ m/foo\s*bar/i && $_ =~ m/bar/i;" c:\temp\xx.txt

Linux：

perl -lne 'print $_ if $_ !~ m/foo\s*bar/i && $_ =~ m/bar/i;' /tmp/xx.txt

xx.txt 包含：

foo is bar
hello bar
foobar
foo     bar
barbar
bar foo
barfoo
foo foo

在命令提示符处执行单行代码的结果：

foo is bar
hello bar
barbar
bar foo
barfoo