有什么方法可以在 Moose 对象中使用 Moose::Exporter 吗？

Question

我正在寻找一种在父 Moose 类中设置一些辅助方法的方法，而不是一个独立的实用程序类。如果可能的话，这将是一种向模块添加 Moose 糖的更透明的方式，因为它不需要明确要求任何辅助模块（因为一切都将通过 extends 声明来实现）。

基于文档中提供的示例，这大致就是我的情况追求：

package Parent;

use Moose;

Moose::Exporter->setup_import_methods(
    with_meta => [ 'has_rw' ],
    as_is     => [ 'thing' ],
    also      => 'Moose',
);

sub has_rw {
    my ( $meta, $name, %options ) = @_;
    $meta->add_attribute(
        $name,
        is => 'rw',
        %options,
    );
}

# then later ...
package Child;

use Moose;
extends 'Parent';

has 'name';
has_rw 'size';
thing;

但这不起作用：

perl -I. -MChild -wle'$obj = Child->new(size => 1); print $obj->size'

String found where operator expected at Child.pm line 10, near "has_rw 'size'"
        (Do you need to predeclare has_rw?)
syntax error at Child.pm line 10, near "has_rw 'size'"
Bareword "thing" not allowed while "strict subs" in use at Child.pm line 12.
Compilation failed in require.
BEGIN failed--compilation aborted.

PS。我还尝试将导出魔法移至角色（with Role; 而不是 extends Parent;），但出现了相同的错误。

Answer 1

这是不支持的，这是有充分理由的。类或角色与糖方法不同，并且在某种程度上不同的东西应该是不同的。如果您的问题是必须“使用”Moose + 自定义糖包，那么您可以通过简单地让您的自定义糖包导出 Moose 来解决这个问题，从您的示例中窃取：

package MySugar;
use strict;
use Moose::Exporter;

Moose::Exporter->setup_import_methods(
    with_meta => [ 'has_rw' ],
    as_is     => [ 'thing' ],
    also      => 'Moose',
);

sub has_rw {
    my ( $meta, $name, %options ) = @_;
    $meta->add_attribute(
        $name,
        is => 'rw',
        %options,
    );
}

然后您只需说：

package MyApp;
use MySugar; # imports everything from Moose + has_rw and thing    
extends(Parent);

has_rw 'name';
has 'size';
thing;

这就是 MooseX 的方式： :POE 以及其他几个包都可以工作。我反对像您在这里建议的那样使用 extends 引入糖，因为类不是糖函数的捆绑，并且两者真的不应该混淆。

更新：要同时引入两者，最简洁的方法是将 Parent 重新设计为应用于 Moose::Object 的角色。

package Parent::Methods;
use 5.10.0;
use Moose::Role;

sub something_special { say 'sparkles' }

然后我们只需将 MySugar 中对 Moose::Exporter 的调用更改为如下所示。

Moose::Exporter->setup_import_methods(
    apply_base_class_roles => 'Parent::Methods',
    with_meta              => ['has_rw'],
    as_is                  => ['thing'],
    also                   => 'Moose',
);

现在您可以简单地说

package MyApp;
use MySugar; 

has_rw 'name';
has 'size';
thing;

package main;
MyApp->new->something_special; # prints sparkles

“我相信这是您想要的最终细节”。