如何在 Perl 中调用存储在哈希中的函数名称？

Question

我确信这在文档中的某个地方有所涉及，但我一直找不到它...我正在寻找语法糖，它可以调用名称存储在哈希中的类上的方法（而不是简单的标量）：

use strict; use warnings;

package Foo;
sub foo { print "in foo()\n" }

package main;
my %hash = (func => 'foo');

Foo->$hash{func};

如果我首先将 $hash{func} 复制到标量变量中，那么我可以调用 Foo->$func 就好了。 . 但是缺少什么才能使 Foo->$hash{func} 正常工作呢？

（编辑：我并不是想通过调用类 Foo 上的方法来做任何特别的事情——这可以很容易地成为一个受祝福的对象（在我的实际代码中它是）；它只是使用类方法更容易编写一个独立的示例。）

编辑2：为了完整性，下面的注释，这就是我实际上正在做的事情（这是在 Moose 属性糖库中，使用 Moose::Exporter)：

# adds an accessor to a sibling module
sub foreignTable
{
    my ($meta, $table, %args) = @_;

    my $class = 'MyApp::Dir1::Dir2::' . $table;
    my $dbAccessor = lcfirst $table;

    eval "require $class" or do { die "Can't load $class: $@" };

    $meta->add_attribute(
        $table,
        is => 'ro',
        isa => $class,
        init_arg => undef,  # don't allow in constructor
        lazy => 1,
        predicate => 'has_' . $table,
        default => sub {
            my $this = shift;
            $this->debug("in builder for $class");

            ### here's the line that uses a hash value as the method name
            my @args = ($args{primaryKey} => $this->${\$args{primaryKey}});
            push @args, ( _dbObject => $this->_dbObject->$dbAccessor )
                if $args{fkRelationshipExists};

            $this->debug("passing these values to $class -> new: @args");
            $class->new(@args);
        },
    );
}

我已将上面标记的行替换为：

        my $pk_accessor = $this->meta->find_attribute_by_name($args{primaryKey})->get_read_method_ref;
        my @args = ($args{primaryKey} => $this->$pk_accessor);

PS。我刚刚注意到，同样的技术（使用 Moose 元类来查找 coderef 而不是假设其命名约定）不能也可用于谓词，如 Class::MOP::Attribute 没有类似的 get_predicate_method_ref 访问器。 :(

Answer 1

Foo->${\$hash{func}};

但为了清楚起见，我可能仍将其写为：

my $method = $hash{func};
Foo->$method;

Answer 2

您存储子例程名称而不是代码引用是否有原因？

例如，

use strict; use warnings;

package Foo;
sub foo { print "in foo()\n" }

package main;
my %hash = (func => \&Foo::foo);

$hash{func}->();

您不会传递类名，但如果这对您很重要，您可以使用类似的东西

my %hash = ( func => sub { return Foo->foo(@_) } );

Answer 3

您是否尝试过UNIVERSALcan方法？你应该能够实现这样的东西：

## untested
if ( my $code = $object->can( $hash{func} ) ) {
    $object->$code();
}

我做了一个无用的单行示例来演示：

perl -MData::Dumper -le 'my %h = ( f => "Dump" ); my $o = Data::Dumper->new( [qw/1 2 3/] ); my $ref = $o->can( $h{f} ); print $o->$ref()'