如何从 Oracle 表中删除表分区？

Question

我发现特定表上使用的分区会损害查询性能，并且希望从表中删除这些分区。有没有简单的方法可以做到这一点？该表有 64 个分区。根据一些初步调查，我提出了以下选项。有更好的办法吗？

1. 将数据复制到另一个表，删除所有分区，然后将数据复制回原始表
2. 将数据复制到另一个表，删除原始表，然后重命名新表并重建索引
3. 使用 MERGE PARTITION 将所有分区合并为一个分区

想法？

Answer 1

我个人认为选项 2 的变体听起来是最好的方法。

1. 创建新表作为 select * from
   旧表
2. 在新表上构建索引 (*)
3. 将旧表重命名为某个名称
   不同
4. 将新表重命名为旧表名称
5. 切换任何外键约束
   旧表到新表。还要传输任何授权、同义词等。
6. 在缓慢的时间内删除旧表

(*)非分区表可能需要与分区表不同的索引。如果您特别重视索引名称，则可以在步骤 6 之后使用 ALTER INDEX ... RENAME TO ... 语法。

这种方法的优点是可以最大限度地减少停机时间（基本上是步骤 3、 4 和 5)。

Answer 2

对表进行分区可能会损害查询性能，但也可以提高性能......
这取决于您的技术解决方案的设计，使用正确的索引、提示等...

如果您想在不停机的情况下从表中删除分区并使正在使用您的表的其他对象失效，您可以使用dbms_redefinition 它将在您配置/计划重新定义过程时分析和移动索引，您可以配置表的结构。

--1. Verify object for Redefinition
--2. Create Partitioned Interim Table
--3. Start the Redefinition Process
--4. Copy Dependent Objects
--5. Synchronize the Interim Table
--6. Complete the Redefinition Process

--Step 1: Verification
BEGIN
  DBMS_REDEFINITION.CAN_REDEF_TABLE('SCHEMA', 'YOUR_CURRENT_TABLE');
END;

--Step 2: Create Partitioned Interim Table
--sql....
create table SCHEMA.YOUR_FUTURE_TABLE
(
  id                        NUMBER(10),
  some_col                  VARCHAR2(100)
);

--Step 3: Redefinition
BEGIN
  DBMS_REDEFINITION.START_REDEF_TABLE(
    uname      => 'SCHEMA',
    orig_table => 'YOUR_CURRENT_TABLE',
    int_table  => 'YOUR_FUTURE_TABLE'
  );
END;

--Step 4: Copy Keys
DECLARE
  num_errors PLS_INTEGER;
BEGIN
  DBMS_REDEFINITION.COPY_TABLE_DEPENDENTS(
    uname            => 'SCHEMA',
    orig_table       => 'YOUR_CURRENT_TABLE',
    int_table        => 'YOUR_FUTURE_TABLE',
    num_errors       => num_errors, 
    copy_indexes     => DBMS_REDEFINITION.CONS_ORIG_PARAMS,
    copy_triggers    => TRUE,
    copy_constraints => TRUE,
    copy_privileges  => TRUE,
    ignore_errors    => FALSE, 
    copy_statistics  => TRUE,  
    copy_mvlog       => FALSE  
  );
  IF num_errors > 0 THEN
    DBMS_OUTPUT.PUT_LINE('There are errors: ' || num_errors);
  END IF;
END;

--Step 5: Synchronize Archive
BEGIN
  DBMS_REDEFINITION.SYNC_INTERIM_TABLE(
    uname      => 'SCHEMA',
    orig_table => 'YOUR_CURRENT_TABLE',
    int_table  => 'YOUR_FUTURE_TABLE'
  );
END;

--Step 6: Complete Redefinition 
BEGIN
  DBMS_REDEFINITION.FINISH_REDEF_TABLE(
    uname      => 'SCHEMA',
    orig_table => 'YOUR_CURRENT_TABLE',
    int_table  => 'YOUR_FUTURE_TABLE'
  );
END;

这将从表中移动数据，而不会使其他对象失效，并且不需要任何停机时间。