如何使用“oneof”在快速检查（Haskell）中

Question

我正在尝试编写一个更改数独的道具，然后检查它是否仍然有效。

但是，我不确定如何正确使用“oneof”函数。您能给我一些提示吗？

prop_candidates :: Sudoku -> Bool
prop_candidates su = isSudoku newSu && isOkay newSu
    where
        newSu       = update su aBlank aCandidate
        aCandidate  = oneof [return x | x <- candidates su aBlank]
        aBlank      = oneof [return x | x <- (blanks su)]

这里有更多信息...

type Pos = (Int, Int)
update :: Sudoku -> Pos -> Maybe Int -> Sudoku
blanks :: Sudoku -> [Pos]
candidates :: Sudoku -> Pos -> [Int]
[return x | x <- (blanks example)] :: (Monad m) => [m Pos]

我已经在这个道具上苦苦挣扎了 3 个小时，所以欢迎任何想法！

Answer 1

我的意思是你的类型混淆了。也就是说，aBlank 不是 Pos，而是 Gen Pos，因此 update su aBlank aCandidate 没有任何意义！事实上，您想要的是一种在给定初始数独的情况下生成新数独的方法；换句话说，一个函数

similarSudoku :: Sudoku -> Gen Sudoku

现在我们可以编写它：

similarSudoku su = do aBlank <- elements (blanks su) 
                      -- simpler than oneOf [return x | x <- blanks su]
                      aCandidate <- elements (candidates su aBlank)
                      return (update su aBlank aCandidate)

甚至更简单：

similarSudoku su = liftM2 (update su) (elements (blanks su)) (elements (candidates su aBlank))

属性看起来像

prop_similar :: Sudoku -> Gen Bool
prop_similar su = do newSu <- similarSudoku su
                     return (isSudoku newSu && isOkay newSu)

因为有实例

Testable Bool
Testable prop => Testable (Gen prop)
(Arbitrary a, Show a, Testable prop) => Testable (a -> prop)

Sudoku ->; Gen Bool 也是可测试（假设实例任意数独）。

Answer 2

在我的博客上，我编写了一个简单的双骰子模拟器，其中包含 QuickCheck 测试使用 oneof 生成有趣的卷。

假设我们有一个超级简单的单行数独：

module Main where
import Control.Monad
import Data.List
import Test.QuickCheck
import Debug.Trace

type Pos = Int
data Sudoku = Sudoku [Char] deriving (Show)

超级简单的数独不应该有重复的值：

prop_noRepeats :: Sudoku -> Bool
prop_noRepeats s@(Sudoku xs) =
  trace (show s) $ all ((==1) . length) $
                   filter ((/='.') . head) $
                   group $ sort xs

您可以使用 trace 生成一个超级简单的数独

instance Arbitrary Sudoku where
  arbitrary = sized board :: Gen Sudoku
    where board :: Int -> Gen Sudoku
          board 0 = Sudoku `liftM` shuffle values
          board n | n > 6 = resize 6 arbitrary
                  | otherwise =
                      do xs <- shuffle values
                         let removed = take n xs
                             dots = take n $ repeat '.'
                             remain = values \\ removed
                         ys <- shuffle $ dots ++ remain
                         return $ Sudoku ys

          values = ['1' .. '9']

          shuffle :: (Eq a) => [a] -> Gen [a]
          shuffle [] = return []
          shuffle xs = do x  <- oneof $ map return xs
                          ys <- shuffle $ delete x xs
                          return (x:ys)

，以显示随机生成的棋盘：

*Main> quickCheck prop_noRepeats 
Sudoku "629387451"
Sudoku "91.235786"
Sudoku "1423.6.95"
Sudoku "613.4..87"
Sudoku "6..5..894"
Sudoku "7.2..49.."
Sudoku "24....1.."
[...]
+++ OK, passed 100 tests.

Answer 3

似乎 aBlank :: Gen Pos 与用作 candidates :: Sudoku -> 的参数的方式不匹配位置 -> [整数]。

我一直在此处查找转换方法Gen a 到 a 这将允许您将其与候选人一起使用。我能看到的最好的是 generate 函数。

告诉我我是否遗漏了什么...