Grails 将请求参数绑定到枚举

Question

我的 Grails 应用程序有大量的枚举，如下所示：

public enum Rating {
    BEST("be"), GOOD("go"), AVERAGE("av"), BAD("ba"), WORST("wo")
    final String id

    private RateType(String id) {
        this.id = id
    }

    static public RateType getEnumFromId(String value) {
        values().find {it.id == value }
    }   
}

如果我有一个如下所示的命令对象：

class MyCommand {
    Rating rating
}

我想（例如）自动将值为“wo”的请求参数转换为 Rating.WORST。

此处描述了定义自定义转换器的过程（在将字符串转换为日期的上下文中）。尽管此过程运行良好，但我不想为每个枚举创建一个实现 PropertyEditorSupport 的类。有更好的选择吗？

Answer 1

我找到了一个令我非常满意的解决方案。

第 1 步： 创建 PropertyEditorSupport 的实现，以将文本与相关 Enum 相互转换

public class EnumEditor extends PropertyEditorSupport {

    private Class<? extends Enum<?>> clazz

    public EnumEditor(Class<? extends Enum<?>> clazz) {
        this.clazz = clazz
    }

    public String getAsText() {
        return value?.id
    }

    public void setAsText(String text) {
        value = clazz.getEnumFromId(text)
    }
}

第 2 步： 定义一个类，将 EnumEditor 注册为各种枚举类的转换器。要更改可通过 id 绑定的枚举类列表，只需修改 BINDABLE_ENUMS

public class CustomPropertyEditorRegistrar implements PropertyEditorRegistrar {

    private static final String REQUIRED_METHOD_NAME = 'getEnumFromId'

    // Add any enums that you want to bind to by ID into this list
    private static final BINDABLE_ENUMS = [Rating, SomeOtherEnum, SomeOtherEnum2]

    public void registerCustomEditors(PropertyEditorRegistry registry) {            

        BINDABLE_ENUMS.each {enumClass ->
            registerEnum(registry, enumClass)
        }
    }

    /**
     * Register an enum to be bound by ID from a request parameter
     * @param registry Registry of types eligible for data binding
     * @param enumClass Class of the enum
     */
    private registerEnum(PropertyEditorRegistry registry, Class<? extends Enum<?>> enumClass) {

        boolean hasRequiredMethod = enumClass.metaClass.methods.any {MetaMethod method ->
            method.isStatic() && method.name == REQUIRED_METHOD_NAME && method.parameterTypes.size() == 1
        }

        if (!hasRequiredMethod) {
            throw new MissingMethodException(REQUIRED_METHOD_NAME, enumClass, [String].toArray())
        }
        registry.registerCustomEditor(enumClass, new EnumEditor(enumClass))
    }
}

第 3 步： 通过在 中定义以下 Spring bean，让 Spring 识别上面的注册表grails-app/conf/spring/resources.grooovy

customPropertyEditorRegistrar(CustomPropertyEditorRegistrar)

Answer 2

因此，默认的数据绑定绑定在枚举名称上，而不是绑定在枚举的单独定义的属性上。您可以按照您提到的方式创建自己的PropertyEditor，或者执行类似于以下的解决方法这：

class MyCommand {
 String ratingId
    Rating getRating() {
     return Rating.getEnumFromId(this.ratingId)
    }
    static constraints = {
     ratingId(validator:{val, obj -> Rating.getEnumFromId(val) != null })
    }
}