条件 XML 文字

Question

我尝试过搜索此问题，但似乎无法在任何地方找到答案，所以希望这里有人可以提供帮助。我想根据计数是否大于 1 插入条件 XML 标记，但不知道该怎么做。

例如，我有两个像这样的 XElement：

<Blob>
<Group>
Stuff 1
</Group>
</Blob>

我

<Blob>
<Group>
Stuff 1
</Group>
<Group>
Stuff 2
</Group>
</Blob>

希望这最终适用于第一个：

<BigGroup>
<Group/>
</BigGroup>

和第二个：

<BigGroup>
<Groups>
<Group/>
<Group/>
</Groups>
</BigGroup>

请注意，在第二个中，它们是包裹在两个组周围的标签。

所以，我想要 XML 文字中的条件。我尝试过的是：

Dim groups = If(<Blob>.<Group>.Count > 1, <Groups/>, Nothing)

Dim bigGroup = <BigGroup><%= groups %><%= from e in <Blob>.<Group> select e %><%= groups%></BigGroup>

但这不起作用。有没有人可以按照上面的要求从 XML Literal 中执行此操作？

Answer 1

您只需将 If 语句放在 XML Literal 中即可。此外，它足够智能，只需引用 <%= %> 内的变量即可输出 IEnumerable(Of XElement)。

这是代码。

Sub Main()
    Dim SingleGroup = <Blob>
                          <Group>Stuff 1</Group>
                      </Blob>

    Dim TwoGroups = <Blob>
                        <Group>Stuff 1</Group>
                        <Group>Stuff 2</Group>
                    </Blob>

    Dim BigGroup1 = BigGroup(SingleGroup.<Group>)

    Dim BigGroup2 = BigGroup(TwoGroups.<Group>)

    Console.WriteLine(BigGroup1)
    Console.WriteLine()

    Console.WriteLine(BigGroup2)
    Console.ReadLine()

End Sub

Function BigGroup(ByVal groups As IEnumerable(Of XElement)) As XElement
    Dim result = <BigGroup>
                     <%= If(groups.Count > 1, _
                         <Groups><%= groups %></Groups>, _
                         groups.SingleOrDefault) %>
                 </BigGroup>
    Return result
End Function

输出是：

<BigGroup>
  <Group>Stuff 1</Group>
<BigGroup>

<BigGroup>
  <Groups>
    <Group>Stuff 1</Group>
    <Group>Stuff 2</Group>
  </Groups>
</BigGroup>