在 bootstrap 中使用 groovy metaClass 模拟 Shiro SecurityUtils

Question

有关更多背景信息，请参阅 http://grails.markmail.org/message/62w2xpbgneapmhpd

我试图在 BootStrap.groovy 中模拟 Shiro SecurityUtils.getSubject() 方法。我决定采用这种方法是因为最新 Shiro 版本中的主题构建器在当前版本的 Nimble 插件（我正在使用）中不可用。我决定尝试使用 SecurityUtils.metaClass，但我有一种感觉，我错过了一些关于元类如何工作的非常基本的东西。作为参考，这里是我的 Trackable 类：

    abstract class Trackable {
       User createdBy
       Date dateCreated
       User lastUpdatedBy
       Date lastUpdated

       static constraints = {
           lastUpdated(nullable:true)
           lastUpdatedBy(nullable:true)
           createdBy(nullable:true)
       }

       def beforeInsert = {
           def subject

           try {
               subject = SecurityUtils.subject
           } catch (Exception e) {
               log.error "Error obtaining the subject.  Message is [${e.message}]"
           }

           createdBy = (subject ? User.get( subject.principal ) :
User.findByUsername("admin"))
       }

       def beforeUpdate = {
           def subject

           try {
               subject = SecurityUtils.subject
           } catch (Exception e) {
               log.error "Error obtaining the subject.  Message is [${e.message}]"
           }

           lastUpdatedBy = (subject ? User.get( subject.principal ) :
User.findByUsername("admin"))
       }
   }

在我的 BootStrap.groovy 中，我有这个：

   def suMetaClass = new ExpandoMetaClass(SecurityUtils)

   suMetaClass.'static'.getSubject = {[getPrincipal:{2}, toString:{"Canned Subject"}] as Subject}

   suMetaClass.initialize()

   SecurityUtils.metaClass = suMetaClass

这有效......有点。如果我从 BootStrap.groovy 打印出主题，我会得到“罐头主题”。如果我尝试创建并保存 Trackable 子类的实例，我会得到：

此方法无法访问 SecurityManager，无论是绑定到
org.apache.shiro.util.ThreadContext 或作为 vm static
单例。请参阅 org.apache.shiro.SecurityUtils.getSubject()
方法 JavaDoc 对预期环境的解释
配置。

我是否遗漏了元类如何工作的一些重要内容？

Answer 1

我知道发生了什么事。在我的 BootStrap 中，我做了这样的事情：

def init = { servletContext->
  switch (Environment.current.name) {
    case "local":
      def suMetaClass = new ExpandoMetaClass(SecurityUtils)
      suMetaClass.'static'.getSubject = {[getPrincipal:{2}, toString:{"Canned Subject"}] as Subject}
      suMetaClass.initialize()
      SecurityUtils.metaClass = suMetaClass

      new TrackableSubClass().save()

      //Create some other domain instances

      SecurityUtils.metaClass = null
  }
  //Create a couple domain instances that aren't environment specific
}

我添加了一些调试语句，并发现我看到的错误发生在 init 闭包的末尾。我做了一些谷歌搜索来仔细检查如何刷新我的休眠会话。然后我做了以下更改：

def sessionFactory

def init = { servletContext->
  switch (Environment.current.name) {
    case "local":
      def suMetaClass = new ExpandoMetaClass(SecurityUtils)
      suMetaClass.'static'.getSubject = {[getPrincipal:{2}, toString:{"Canned Subject"}] as Subject}
      suMetaClass.initialize()
      SecurityUtils.metaClass = suMetaClass

      new TrackableSubClass().save()

      //Create some other domain instances

      sessionFactory.currentSession.flush()

      SecurityUtils.metaClass = null
  }
  //Create a couple domain instances that aren't environment specific
}

这似乎已经完全解决了问题，现在我应该能够从 Trackable 中删除繁琐的 try/catch 块。 :-)