如何使用 File::Find 仅打印具有相对路径的文件？

Question

我在下面的代码中使用 File::Find 来查找 /home/user/data 路径。

use File::Find;

my $path = "/home/user/data";
chdir($path);
my @files;

find(\&d, "$path");

foreach my $file (@files) {
print "$file\n";
}

sub d {
-f and -r and push  @files, $File::Find::name;
}

当我将目录路径更改为我需要搜索文件的路径时，它仍然为我提供了带有完整路径的文件。即，

/home/user/data/dir1/file1
/home/user/data/dir2/file2
and so on...

但我想要类似的输出，

dir1/file1
dir2/file2
and so on...

有人可以建议我查找文件并仅从当前工作目录显示的代码吗？

Answer 1

下面将打印 $base 下所有文件相对于 $base 的路径（不是当前目录）：

#!/usr/bin/perl
use warnings;
use strict;

use File::Spec;
use File::Find;

# can be absolute or relative (to the current directory)
my $base = '/base/directory';
my @absolute;

find({
    wanted   => sub { push @absolute, $_ if -f and -r },
    no_chdir => 1,
}, $base);

my @relative = map { File::Spec->abs2rel($_, $base) } @absolute;
print $_, "\n" for @relative;

Answer 2

直接删除它怎么样：

foreach my $file (@files) {
$file =~ s:^\Q$path/::;
print "$file\n";
}

注意：这实际上会更改@files的内容。

根据评论，这不起作用，所以让我们测试一个完整的程序：

#!/usr/local/bin/perl
use warnings;
use strict;
use File::Find;

my $path = "/usr/share/skel";
chdir($path);
my @files;

find(\&d, "$path");

foreach my $file (@files) {
$file =~ s:^\Q$path/::;
print "$file\n";
}

sub d {
-f and -r and push  @files, $File::Find::name;
}

我得到的输出是

$ ./find.pl
dot.cshrc
dot.login
dot.login_conf
dot.mailrc
dot.profile
dot.shrc

这对我来说似乎工作正常。我也用带子目录的目录测试过，没有问题。