Grails：如何对注入服务的命令对象进行单元测试

Question

我正在尝试测试控制器 它有一个带有数据绑定的 Command 对象。

命令对象中注入了一个服务。

但是当我尝试测试命令对象注入的服务方法时 从未找到，因为它从未“注入”

有没有办法在命令对象内模拟服务？

测试方法

void testLoginPasswordInvalid() {
    mockRequest.method = 'POST'
    mockDomain(User, [new User(login:"freddy", password:"realpassword")])
    mockLogging(UserService) // userService mocked
    MockUtils.prepareForConstraintsTests(LoginCommand)

    def userService = new UserService()
    def user = userService.getUser("freddy")//Gets called and returns the mockDomain
    assert userService.getUser("freddy")//Passes

    def cmd = new LoginCommand(login:"freddy", password:"letmein")
    cmd.validate() // Fails (userService is nevr injected)
    controller.login(cmd)
    assertTrue cmd.hasErrors()
    assertEquals "user.password.invalid", cmd.errors.password
    assertEquals "/store/index", renderArgs.view
}

找不到 userService 的 getUser() 方法

Cannot invoke method getUser() on null object
java.lang.NullPointerException: Cannot invoke method getUser() on null object

代码

被调用的控制器的登录方法，

def login = { LoginCommand cmd ->
  if(request.method == 'POST') {
     if(!cmd.hasErrors()){
       session.user = cmd.getUser()
       redirect(controller:'store')
     }
     else{
       render(view:'/store/index', model:[loginCmd:cmd])
     }
  }else{

    render(view:'/store/index')
  }
}

命令对象中注入了“userService”。

验证器调用此 userService 来查找用户

 class LoginCommand {

    def userService

    String login
    String password

    static constraints = {
      login blank:false, validator:{ val, cmd ->
          if(!cmd.userService.getUser()){
             return "user.not.found"
          }
      }
 }

userService.getUser() 如下所示。

class UserService {

    boolean transactional = true

    User getUser(String login) {
        return User.findByLogin(login)

    }
}

Answer 1

服务注入是使用 Spring 按名称自动装配来完成的。 （Grep autowire 的 Grails 源代码树可以找到一个不错的代码片段，您可以使用它在集成测试中自动连接您的控制器。）这仅在集成测试中起作用，其中有一个 Spring 应用程序周围的上下文有可以注入的bean。

在单元测试中，您必须自己执行此操作，因为您的东西周围没有 Spring-land。这可能很痛苦，但给您带来了一些好处：

1) 可以轻松注入服务的模拟版本 - 例如，使用 Expando - 以便更密切地指定控制器协作服务的行为，并允许您仅测试控制器逻辑而不是一起测试控制器和服务。 （您当然也可以在单元测试中执行后者，但您可以选择如何连接它。）

2）它迫使您明确控制器的依赖关系 - 如果您依赖它，您的测试会显示它。这使它们成为控制器行为的更好规范。

3）您只能模拟您的控制器所依赖的外部协作者。这有助于您的测试不那么脆弱——当事情发生变化时，不太可能需要改变。

简短的回答：您的测试方法需要 cmd.userService = userService 行。

Answer 2

约翰说的很中肯。一个例子可能是：

def mockUsers = [new User(login:"freddy", password:"realpassword")]
mockDomain(User, mockUsers)

def userService = [getUser:{String login -> mockUsers[0]}] as UserService

def cmd = new LoginCommand (/*arguments*/)
cmd.userService = userService

您可以在 http://groovy.codehaus.org/Groovy 查找模拟对象的其他方法+模拟