证明 f (f bool) = bool

Question

我如何在 coq 中证明函数 f 接受 bool true|false 并返回 bool true|false （如下所示） ，当对单个 bool true|false 应用两次时，将始终返回相同的值 true|false：

(f:bool -> bool)

例如，函数 f 只能执行以下操作： 4件事，让我们调用函数b的输入：

• 总是返回true
• 总是返回false
• 返回b（即如果 b 为 true，则返回 true，反之亦然）
• 返回 not b（即，如果 b 为 true，则返回 false，反之亦然）

因此，如果函数始终返回 true：

f (f bool) = f true = true

如果函数始终返回 false，我们将得到：

f (f bool) = f false = false

对于其他情况，假设函数返回不是 b

f (f true) = f false = true
f (f false) = f true = false

在两种可能的输入情况下，我们总是以原始输入结束。如果我们假设函数返回 b，情况也是如此。

那么如何在 coq 中证明这一点呢？

Goal forall (f:bool -> bool) (b:bool), f (f b) = f b.

Answer 1

Goal forall (f:bool -> bool) (b:bool), f (f (f b)) = f b.
Proof.
intros.
remember (f true) as ft.
remember (f false) as ff.
destruct ff ; destruct ft ; destruct b ; 
    try rewrite <- Heqft ; try rewrite <- Heqff ; 
    try rewrite <- Heqft ; try rewrite <- Heqff ; auto.
Qed.

Answer 2

稍微短一点的证明：

Require Import Sumbool.

Goal forall (f : bool -> bool) (b:bool), f (f (f b)) = f b.
Proof.
  destruct b;                             (* case analysis on [b] *)
    destruct (sumbool_of_bool (f true));  (* case analysis on [f true] *)
    destruct (sumbool_of_bool (f false)); (* case analysis on [f false] *)
    congruence.                           (* equational reasoning *)
Qed.

Answer 3

在 SSReflect 中：

Require Import ssreflect.

Goal forall (f:bool -> bool) (b:bool), f (f (f b)) = f b.
Proof.
move=> f.
by case et:(f true); case ef:(f false); case; rewrite ?et ?ef // !et ?ef.
Qed.

Answer 4

感谢精彩的任务！多么可爱的定理啊！

这是使用 Coq 的 C-zar 声明式证明风格的证明。它比命令式的要长得多（尽管可能是因为我的技能太低）。

Theorem bool_cases : forall a, a = true \/ a = false.
proof.
    let a:bool.
    per cases on a.
    suppose it is false.
        thus thesis.
    suppose it is true.
        thus thesis.
    end cases.
end proof. Qed.

Goal forall (b:bool), f (f (f b)) = f b.
proof.
    let b:bool.
    per cases on b.

    suppose it is false.
        per cases of (f false = false \/ f false = true) by bool_cases.
        suppose (f false = false).
            hence (f (f (f false)) = f false).
        suppose H:(f false = true).
            per cases of (f true = false \/ f true = true) by bool_cases.
            suppose (f true = false).
                hence (f (f (f false)) = f false) by H.
            suppose (f true = true).
                hence (f (f (f false)) = f false) by H.
            end cases.
        end cases.

    suppose it is true.
        per cases of (f true = false \/ f true = true) by bool_cases.
        suppose H:(f true = false).
            per cases of (f false = false \/ f false = true) by bool_cases.
            suppose (f false = false).
                hence (f (f (f true)) = f true) by H.
            suppose (f false = true).
                hence (f (f (f true)) = f true) by H.
            end cases.
        suppose (f true = true).
            hence (f (f (f true)) = f true).
        end cases.

end cases.
end proof. Qed.