MS Excel 2003 - 处理形状时 Excel VBA 中的简单取消选择问题

Question

所以我有一个 Excel 工作簿，其中有一个全局映射方案。所以我在 Excel 中为每个国家/地区都有一个形状。根据区域选择，相对于数据/查询，它将以各种方式遮蔽区域/国家。

所以我知道如何在颜色、渐变阴影等方面操纵每个形状......

我不知道该怎么做是“取消选择”子例程末尾的形状。我的代码看起来像这样（非常简单）：

sheet1.shapes("CountryName").select
selection.shaperange.fill.solid
selection.shaperange.fill.visible = true
selection.shaperange.fill.forecolor.rgb=rgb(110,110,110)
selection.shaperange.fill.onecolorgradiend msogradienthorizontal, 2, 0.45

好吧，从一个形状/国家/地区到另一个形状/国家/地区，“取消选择”并不是什么大不了的事情，因为焦点会跳跃，但最后？？？

我猜测/尝试了很多东西，但可惜没有运气，

谢谢！

Answer 1

你的源代码最后一行有一个拼写错误，...gradiend --> ...渐变

selection.shaperange.fill.onecolorgradienT msogradienthorizontal, 2, 0.45

“取消选择”形状对象的一种非常简单的方法是添加这行代码，

sheet1.[A1].select

这会将焦点移动到工作表中的单元格 A1 ，从而远离您的对象。非常粗鲁，我不推荐这样做。我也不建议按照上面的建议“保存当前选择”，因为我们不知道光标是在单元格中还是在另一个（范围）对象中。

更好的方法是在整个脚本中完全避免“选择”。将您的形状分配给一个对象并操作该对象（注意：我在测试中使用第一个可用对象在sheet3中进行模拟），即

Sub test()
Dim MyShape As Shape
    Set MyShape = Sheet3.Shapes(1) ' or whatever shape according to the user input
    With MyShape.Fill
        .Solid
        .Visible = True
        .ForeColor.RGB = RGB(110, 110, 110)
        .OneColorGradient msoGradientHorizontal, 2, 0.45
    End With
End Sub

更好的是，如果您正在处理一个为您提供形状名称的列表，请执行以下

Sub Test()
    '
    ' get the shape's name into ShapeName
    ' ...

    ColorShape Sheet3.Shapes(ShapeName)

    ' ...

End Sub

Sub ColorShape(MyShape As Shape)
    With MyShape.Fill
        .Solid
        .Visible = True
        .ForeColor.RGB = RGB(110, 110, 110)
        .OneColorGradient msoGradientHorizontal, 2, 0.45
    End With
End Sub

操作这有帮助
祝你好运麦克D

Answer 2

您不能简单地记录所选的原始单元格吗？

Dim oCell as Range
set oCell = activecell

'' Do stuff here

oCell.activate

更新：这一段代码记录了当前的选择，然后在选择范围（“A4”）后重新选择它。在不知道工作簿中有哪些形状的情况下，我无法验证这是否有效，但到目前为止我已经测试过了。

Set mySel = Application.Selection
[A4].Select
mySel.Select

Answer 3

我遇到了类似的问题，我需要在单击形状后隐藏它。我的解决方案是使用 SendKeys 来转义选择

SendKeys "{Esc}"