使用removeChild方法时出现错误

Question

祝大家万圣节前夕快乐:)

我今天的问题是删除子对象时遇到的 DisplayObject 错误。我有代码将启动（addChild）视频容器和视频控件以及添加关闭按钮。 现在关闭按钮工作正常，一切正常，删除视频和控件，我能够再次选择另一个视频，但是当您第二次单击“关闭”时，我收到此错误：

ArgumentError：错误#2025：提供的 DisplayObject 必须是调用者的子级。 at flash.display::DisplayObjectContainer/removeChild()

因此，我将问题范围缩小到删除 videoContainer（保存视频对象）的位置

播放视频的代码：

public function videoSwitch(videoName):void
{
    nv.closeOut();
    nv.resetNav = false;

    if (!videoPlaying)
    {
        vc = new VideoClass(videoName, videoHolder);
        vc.addEventListener("KillMovie", removePlayer);
        container.addChild(videoContainer);
        container.addChild(vc);
        //container.addChildAt(videoContainer, 1);
        //container.addChildAt(vc, 2);
        videoPlaying = true;
        closeVideo();
    }

    else if (videoPlaying)
    {
        vc.clearSource();
        container.removeChild(videoContainer);
        container.removeChild(vc);

        vc = new VideoClass(videoName, videoHolder);
        vc.addEventListener("KillMovie", removePlayer);
        container.addChild(videoContainer);
        container.addChild(vc);
        //container.addChildAt(videoContainer, 1);
        //container.addChildAt(vc, 2);
        closeVideo();
    }
        trace("videoPlaying = "+videoPlaying+"\r");
}

关闭视频播放器代码： 您可以在我的评论中看到我尝试过的其他代码，但仍然收到错误。

function closeVideo():void 
{
    closeBtn.visible = true;
    closeBtn.x = 770;
    closeBtn.y = 20;
    closeBtn.buttonMode = true;
    container.addChild(closeBtn);
    closeBtn.addEventListener(MouseEvent.MOUSE_UP, closeButtonClicked);

    function closeButtonClicked(event:MouseEvent):void 
    {
        vc.clearSource();
        container.removeChild(videoContainer);
        //container.removeChildAt(videoContainer, 1);
        container.removeChild(vc);
        videoPlaying = false;
        closeBtn.visible = false;
    }
}

现在我的电影工作正常，但我担心这个错误发生在后台（并显示在我的输出窗口中）最终会在其他地方引起问题:(

提前感谢您对这个问题的关注！:)

---

更新： 已修复！问题是我删除了kill VC侦听器，但忘记删除愚蠢的Close Button Mouse_Event侦听器:(

function addCloseButton():void 
{
    container.addChild(closeBtn);
    closeBtn.addEventListener(MouseEvent.MOUSE_UP, closeButtonClicked);

    function closeButtonClicked(event:MouseEvent):void 
    {
        videoPlaying=false;
        vc.clearSource();
        removeContainerChildren(); // <- thx Joel!
        closeBtn.removeEventListener(MouseEvent.MOUSE_UP, closeButtonClicked);
        //^ Forgot this line - thx Jotham!
        container.removeChild(closeBtn);
    }
}

不知道此图是否有帮助，但是：

Answer 1

这是避免该错误的一种方法：

    public function videoSwitch(videoName):void
    {
        nv.closeOut();
        nv.resetNav = false;

        if (videoPlaying)
        {
            vc.clearSource();
            removeContainerChildren()
        }

        addContainerChildren();
        closeVideo();
    }

    protected function removeContainerChildren():void
    {
        if(container.contains(videoContainer))
            container.removeChild(videoContainer);
        if(container.contains(vc))
        {
            container.removeChild(vc)   
            vc.removeEventListener("KillMovie", removePlayer)
        }
    }

    protected function addContainerChildren():void
    {
        videoPlaying = true;
        vc = new VideoClass(videoName, videoHolder);
        vc.addEventListener("KillMovie", removePlayer, false, 0, true); 
        container.addChild(videoContainer);
        container.addChild(vc);

        trace("videoPlaying = "+videoPlaying+"\r");
    }

Answer 2

你移除过监听器吗？您很可能会多次触发它。

Answer 3

试试这个：

 container.removeChild(container.videoContainer);
 container.removeChild(container.vc);

Answer 4

我有一种感觉，是其他一些代码导致了实际的问题。如果 videouPlaying 变量在其他地方发生了更改，从而导致您删除了尚不存在的内容，则此错误是有意义的。也许检查一下您是否没有在其他地方更改此变量。

Answer 5

这是另一种非常巧妙的方法，通常不推荐，但它肯定会确保 videoContainer/vc 从它所在的 DisplayList 中删除。

private function removeFromStack(target:DisplayObject):void
{
    if (target.parent)
        target.parent.removeChild(target);
}

private function removeVideo():void
{
    removeFromStack(vc);
    removeFromStack(videoContainer);
    vc = videoContainer = null;
}

重申一下，这不是首选方法，但它不会出现错误。如果您开始收到“无法访问空对象引用”错误，那么正如前面的人所建议的那样，事件侦听器或其他一些依赖项仍然由有问题的 DisplayObject 持有。

希望这有帮助