在 Access 表单上将控件分组在一起

Question

我有一个 Access2003 表单，我想将多个控件组合在一起并通过 VBA 代码以编程方式更改可见性。

这可能吗？我确实知道我可以通过格式对项目进行分组 ->组，但如果我这样做，如何在代码中引用整个组？

谢谢

Answer 1

您可以将所有控件放置在组框控件中，然后更改组框本身的可见性。

您还可以在要分组的每个控件的标记属性中添加一个值，然后在 VBA 中循环遍历该控件并检查该值并更改那里的可见性。

将要分组的所有控件的 tag 属性设置为 groupABC 或任何您想要的值。

然后在代码中的某个地方使用它来循环表单控件并检查它。

Dim ctrl As Control
For Each ctrl In Me.Controls
    If ctrl.Tag = "groupABC" Then
        ctrl.Visible = False
    End If
Next

Answer 2

为了详细说明我对使用自定义集合的评论，您需要在表单的模块中执行类似的操作：

  Private mcolGroupABC As New Collection

  Private Sub IntializeCollections()
    Dim ctl As Control

    If mcolGroupABC.Count = 0 Then
       For Each ctl in Me.Controls
         If ctl.Tag = "GroupABC" Then
            mcolGroupABC.Add ctl, ctl.Name
         End If
       Next ctl
       Set ctl = Nothing
    End If
  End Sub

  Private Sub Form_Load()
    Call InitializeCollections
  End Sub

  Private Sub ShowControls(mcol As Collection, bolShow As Boolean)
    Dim ctl As Control

    For Each ctl In mcol
      ctl.Visible = bolShow
    Next ctl
    Set ctl = Nothing
  End Sub

要隐藏控件，您需要执行以下操作：

  Call ShowControls(mcolGroupABC, False)

并显示它们：

  Call ShowControls(mcolGroupABC, True)

这很简单，不是吗？

这是我一直在我的应用程序中使用的代码，自从大约 10 年前第一次实现它以来，我就一直在使用它，并且注意到使用自定义集合比遍历整个控件集合要好。

唯一需要注意的是，如果其中一个控件具有焦点，如果您尝试隐藏它，则会出错。这很容易解决，因为如果您隐藏一组控件，那么在执行此操作之前肯定有一个合适的位置来设置焦点。

Answer 3

我喜欢 Joel Gauvreau 建议的标签属性。其他可能性包括选项卡控件和/或子表单。

Answer 4

更有效的方法是将所有相关控件添加到选项卡控件中。您使用单个页面创建一个 Tab 控件，然后将 Tab 控件的 Style 设置为 None，并将 Back Style 设置为 Transparent.这样，Tab 控件的视觉外观就会消失，但其分组语义仍然存在。然后将控件添加到页面，可以在内部创建它们，也可以将现有控件剪切+粘贴到页面中（请记住在粘贴后重新启用事件过程）。

如果只是可见性问题，现在您只需设置 Page 控件的 Visible 属性，属于该控件的所有控件都会显示或隐藏。

但是，如果您需要对每个分组控件执行更详细的操作，则可以使用以下方法迭代它们：

  Dim ctl As control
  
  For Each ctl In page_control.Controls
     ctl.Visible = False
  Next

您还可以使用 .Tag 或 .Type 属性对这些控件执行不同的操作。