如何使用 awk 脚本删除选定的行？

Question

我正在通过一些 awk 命令传输程序的输出，而且我几乎已经到达了我需要的位置。到目前为止的命令是：

myprogram | awk '/chk/ { if ( $12 > $13) printf("%s %d\n", $1, $12 - $13); else  printf("%s %d\n", $1, $13 - $12)  }  ' | awk '!x[$0]++'

最后一位是穷人的 uniq，它在我的目标上不可用。假设上面的命令有机会产生如下输出：

GR_CB20-chk_2, 0
GR_CB20-chk_2, 3
GR_CB200-chk_2, 0
GR_CB200-chk_2, 1
GR_HB20-chk_2, 0
GR_HB20-chk_2, 6
GR_HB20-chk_2, 0
GR_HB200-chk_2, 0
GR_MID20-chk_2, 0
GR_MID20-chk_2, 3
GR_MID200-chk_2, 0
GR_MID200-chk_2, 2

我想要的是这样的：

GR_CB20-chk_2, 3
GR_CB200-chk_2, 1
GR_HB20-chk_2, 6
GR_HB200-chk_2, 0
GR_MID20-chk_2, 3
GR_MID200-chk_2, 2

也就是说，我想仅打印给定标记（第一个“字段”）具有最大值的行。上面的示例代表了 at 数据，因为输出将被排序（就好像它已通过 sort 命令进行管道传送一样）。

Answer 1

基于我对类似需求的答案 ，这个脚本使事情保持有序并且不会累积一个大数组。它打印每组中具有最高值的行。

#!/usr/bin/awk -f
{
    s = substr($0, 0, match($0, /,[^,]*$/))
    if (s != prevs) {
        if ( FNR > 1 ) print prevline
        prevval = $2
        prevline = $0
    }
    else if ( $2 > prevval ) {
        prevval = $2
        prevline = $0
    }
    prevs = s
}
END {
    print prevline
}

Answer 2

如果您不需要项目的顺序与 myprogram 输出的顺序相同，则可以使用以下方法：

... | awk '{ if ($2 > x[$1]) x[$1] = $2 } END { for (k in x) printf "%s %s", k, x[k] }'