Delphi：泛型和 TObjectList

Question

我创建了一个像

TMyClass = class(TObject)
private
  FList1: TObjectList<List1>;
  FList2: TObjectList<List2>;
public
end;

现在这样的类，我想要一个方法FillArray(Content);，最好应该实现一次，即没有重载。我相信使用泛型是可能的，但我对这些野兽缺乏经验，无法实际实现它。有人知道吗？提前致谢！

Answer 1

我相信以下内容仅适用于 Delphi 2010。因为它取决于 TArray的声明在系统单元中，看起来像这样：

  TArray<T> = array of T;

这是我开发的用于帮助 TArray 到 List 转换的单元，

unit ListTools;

interface                
uses Generics.Collections;
type
 TListTools = class(TObject)
 public
    // Convert TList<T> to TArray<T>
    class function ToArray<T>(AList: TList<T>): TArray<T>;
    // Append Array elements in AValues to AList
    class procedure AppendList<T>(AList : TList<T>;AValues : TArray<T>);
    // Clear List and Append Values to aList
    class procedure ToList<T>(AList : TList<T>;AValues : TArray<T>);
 end;

implementation

{ TListTools }

class procedure TListTools.AppendList<T>(AList: TList<T>; AValues: TArray<T>);
var
  Element : T;
begin
  for Element in AValues do
  begin
     AList.Add(Element);
  end;
end;

class function TListTools.ToArray<T>(AList: TList<T>): TArray<T>;
// taken from rtti.pas
var
  i : Integer;
begin
  SetLength(Result, AList.Count);
  for i := 0 to AList.Count - 1 do
    Result[i] := AList[i];
end;

class procedure TListTools.ToList<T>(AList: TList<T>; AValues: TArray<T>);
begin
   AList.Clear;
   AppendList<T>(AList,AValues);
end;

end.

因为 TList是 TObjectList的父类。这应该与 TObjectList一起使用虽然我还没有尝试过。