将Scheme表达式转换为字符串

Question

给定一个表达式 '(lambda (x) x) 我如何将其转换为字符串。我认为符号->字符串可以完成这项工作，但不，它不能不是符号。

例如对于宏到字符串： (to-string (lambda(x) x)) 这应该返回>> “(lambda (x) x)”

任何想法，谢谢

Answer 1

标准方案（至少在 R5RS 意义上）无法做到这一点，因此如果您想要可移植代码，您需要自己遍历结构。乏味，但不太复杂（即使对于点列表）。
但如果您只想要一些工作版本，那么您应该查看您的实现手册并搜索执行此操作的方法。答案几乎总是很简单，例如，在 PLT 方案中，您可以使用 (format "~s" '(lambda ...))

Answer 2

表达式'(lambda (x) x) 是一个带引号的列表。

表达式(lambda (x) x)是运行时的某种已编译的、不透明的、可执行的内部对象。

symbol->string 只是将符号转换为字符串，即字符序列。

如果您正在使用列表，则只需遍历该列表并打印出各个组件即可。事实上 (write '(lambda (x) x)) 将简单地打印出列表。

许多方案都有类似于 (with-output-to-string ... ) 的东西，它返回写入标准端口的所有输出的字符串。

然而，如果你这样做(write (lambda (x) x))，你会得到谁知道什么。转储可执行函数类型时，您将获得实现提供的任何内容。有些可能会打印显示源代码的“反汇编”。其他人可能只是打印 #function 或同样无用的东西。

简而言之，如果您只想打印出一个列表，有各种机制可以实现。

如果您想打印出已编译函数的源代码，那是一个完全不同的问题，非常依赖于实现，而且很可能是不可能的。

Answer 3

如果您使用的是 R6RS 兼容方案，则可以使用 write 函数结合 使用字符串输出端口调用。

#!r6rs
(import (rnrs base)
        (rnrs io ports)   ;for call-with-string-output-port
        (rnrs io simple)) ;for write

;; Produces a string representation of the S-Expression e
(define (expr->string e)
  (call-with-string-output-port
   (lambda (out) (write e out))))

一些例子：

> (expr->string '(lambda (x) (+ x 1)))
"(lambda (x) (+ x 1))"
> (expr->string '(lambda (x) (string-append x " and cheese!")))
"(lambda (x) (string-append x \" and cheese!\"))"

顺便说一句，通常也可以使用 read 结合 开放字符串输入端口。

;; Produces the S-Expression represented by the string.
;; In most cases this will be a left-inverse of expr->string,
;; so that (string->expr (expr->string e)) = e.
;; If the string has multiple S-Expressions represented
;; in it, this only returns the first one.
(define (string->expr s)
  (read (open-string-input-port s)))

一些例子：

> (string->expr "(lambda (x) (+ x 1))")
(lambda (x) (+ x 1))
> (equal? (string->expr "(lambda (x) (+ x 1))")
          '(lambda (x) (+ x 1)))
#t
> (equal? (string->expr (expr->string '(lambda (x) (+ x 1))))
          '(lambda (x) (+ x 1)))
#t

Answer 4

使用 pretty-format：

(pretty-format v [columns]) → string?

Answer 5

你应该走过这些缺点。当一个新的cons开始时写“(”，当它结束时写“)”并使用symbol->string作为conses内的符号。

您可以通过类型分派来扩展它。方案中可能也存在漂亮的印刷品吗？

Answer 6

我认为这是一个简单的代码，可以满足您的要求。
它不使用特定于实现的东西并且非常简单。

但请注意，它不能正确处理字符串中的特殊字符（例如“a\”b\“c”将变成“a”b“c”）。

(define join
    (lambda (l delim to-str)
      (fold-left
        (lambda (str elem)
          (string-append str delim (to-str elem)))
        (to-str (car l))
        (cdr l))))
(define sexpr->string 
      (lambda (sexpr)
        (cond 
          ((number? sexpr) (number->string sexpr))
          ((symbol? sexpr) (symbol->string sexpr))
          ((boolean? sexpr) (if sexpr "#t" "#f"))
          ((string? sexpr) (string-append "\"" sexpr "\""))
          ((char? sexpr) (string-append "#\\" (string sexpr)))
          ((vector? sexpr) 
           (let ((s-vec (join (vector->list sexpr) " " sexpr->string)))
             (string-append "#(" s-vec ")")))
          ((null? sexpr) "()")
          ((list? sexpr) (string-append "(" (join sexpr " " sexpr->string) ")"))

          ((pair? sexpr) 
           (let ((s-car (sexpr->string (car sexpr)))
                 (s-cdr (sexpr->string (cdr sexpr))))
             (string-append "(" s-car " . " s-cdr ")"))))))