在 vb.net 中获取垂直滚动条位置作为整数

Question

我有一个 RichTextBox，我需要找到垂直滚动条的位置。

没有 Pinvoke 有什么办法可以做到这一点吗？如果没有，有什么方法可以使用 Pinvoke 来做到这一点？

我需要返回一个整数值。

感谢您的帮助！

Answer 1

嗯，是的，Jay 的解决方案实现了承诺：它改变了滚动条的位置。它没有改变的是 RichTextBox 内容的位置。

这是我在 codeproject.com 找到的解决方案： https: //www.codeproject.com/Questions/293542/VB-Net-Custome-RichTextBox-SetScrollPos

Public Class Rtbscrollfix
    Inherits RichTextBox

    <DllImport("user32.dll")>
    Private Shared Function SendMessage(ByVal hWnd As IntPtr, ByVal Msg As Integer, ByVal wParam As IntPtr, ByRef lParam As System.Drawing.Point) As Integer
    End Function

    Private Const WM_USER = &H400
    Private Const EM_GETSCROLLPOS = WM_USER + 221
    Private Const EM_SETSCROLLPOS = WM_USER + 222

    Public Property ScrollY() As Integer
        Get
            Dim pt As New System.Drawing.Point
            SendMessage(Me.Handle, EM_GETSCROLLPOS, 0, pt)
            Return pt.Y
        End Get
        Set(value As Integer)
            SendMessage(Me.Handle, EM_SETSCROLLPOS, 0, New System.Drawing.Point(0, value))
        End Set
    End Property

End Class

Answer 2

如果没有 PInvoke，我不知道有什么方法可以做到这一点。您可以使用 PInvoke 调用 GetScrollPos。

您可以尝试以下方法。

第 1 步：通过扩展标准 RichTextBox 创建自定义 RichTextBox 控件。

Imports System
Imports System.Collections.Generic
Imports System.Text
Imports System.Runtime.InteropServices
Imports System.Windows.Forms

Namespace WindowsFormsApplication1

    Public Class MyRichTextBox
        Inherits RichTextBox
        <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
        Public Shared Function GetScrollPos(ByVal hWnd As IntPtr, ByVal nBar As Integer) As Integer
        End Function

        <DllImport("user32.dll")> _
        Private Shared Function SetScrollPos(ByVal hWnd As IntPtr, ByVal nBar As Integer, ByVal nPos As Integer, ByVal bRedraw As Boolean) As Integer
        End Function

        Private Const SB_HORZ As Integer = &H0
        Private Const SB_VERT As Integer = &H1

        ''' <summary>
        ''' Gets and Sets the Horizontal Scroll position of the control.
        ''' </summary>
        Public Property HScrollPos() As Integer
            Get
                Return GetScrollPos(DirectCast(Me.Handle, IntPtr), SB_HORZ)
            End Get
            Set(ByVal value As Integer)
                SetScrollPos(DirectCast(Me.Handle, IntPtr), SB_HORZ, value, True)
            End Set
        End Property

        ''' <summary>
        ''' Gets and Sets the Vertical Scroll position of the control.
        ''' </summary>
        Public Property VScrollPos() As Integer
            Get
                Return GetScrollPos(DirectCast(Me.Handle, IntPtr), SB_VERT)
            End Get
            Set(ByVal value As Integer)
                SetScrollPos(DirectCast(Me.Handle, IntPtr), SB_VERT, value, True)
            End Set
        End Property
    End Class
End Namespace

这将向标准 RichTextBox 添加两个属性：HScrollPos 和 VScrollPos。这些属性将允许您获取和设置控件中的水平和垂直滚动条位置。

第 2 步：创建一个测试表单并尝试您的控件。

在与自定义控件相同的项目中创建 Winform。将自定义控件拖放到测试窗体中，并在窗体上添加一个按钮。在窗体的 Click 事件中，添加以下代码以查看自定义控件的垂直滚动位置。

Console.WriteLine(myRichTextBox1.VScrollPos)

需要注意的一些事项：

1. 如果您的控件当前未
   显示垂直滚动条时，
   调用 HScrollPos 会使你的
   程序。有几个明显的
   解决这个问题的方法（检查
   之前显示过滚动条
   检查财产，或作出
   垂直滚动条始终可见等）。

2. 取决于控制方式（以及
   可能的形式）的大小（不
   提及文本内容的变化
   的控制），设置
   VScrollPos 可能会使您的程序崩溃或
   不将其恢复到原来的位置
   当 VScrollPos 值为
   保存。

3. 我从来没有使用过这个代码。我
   我以为你的问题是
   有趣并且做了一点
   研究得出我的答案。