使用ColdFusion将上传的图像保存到服务器

Question

我被我认为创建功能以允许用户将图片上传到服务器目录的相对简单的任务所困扰，并且正在寻求一些帮助。

我有一个带有简单界面的简单表单，传递一个名为“imagedata”的变量，它是从文件输入传递的数据，一个名为“name”的变量，它是指定的图像名称，以及一个名为“imagetype”的变量，它传递一个文件扩展名。

我在函数（处理程序）中使用的用于保存此文件的代码如下：

<cfset form.imageName = form.name & "." & form.imagetype />
...
<cffile action="write" file="#sitepath#storage/bannerImages/#form.imagename#" output="#form.imageData#" />

这显然不起作用；它将使用正确的名称保存文件，但不会正确保存文件并且不会渲染为图像。我认为这是相对简单的事情，而且我认为我忽略了一些东西，因为我在谷歌上没有找到任何东西，这很奇怪。帮助解决这个问题将不胜感激。

Answer 1

不要使用 action="write"，使用 action="upload"。

示例：

<cffile
    action       = "upload"
    fileField    = "ImageData"
    destination  = "/tmp/uploads"
    accept       = "image/jpg"
    nameConflict = "MakeUnique"
/>

这会将文件放置在 /tmp/uploads 中（例如，在 Windows 上使用 d:/tmp/uploads） - 这是一个无法在线访问的目录。

此时，您必须验证该文件是否如其所声称的那样 - 具有适当尺寸和文件大小的图像文件，而不是屏蔽的 EXE 或 嵌入 ZIP。

一旦您确信该文件可以安全地托管在您的服务器上，您就可以将其移动到适当的目录并将名称设置为所选的名称。

类似...

<cfif cffile.FileWasSaved>

    <cfset UploadedFileName = cffile.ServerDirectory & '/' & cffile.ServerFile />

    <cfif NOT IsImageFile( UploadedFileName )>
        <cfthrow message="Uploaded file not an image." />
    </cfif>

    <!--- INFO: Checks if zip embedded in image. --->
    <cftry>
        <cfzip action="list" file="#UploadedFileName#" name="tmp"/>
        <cfthrow message="Embedded zip files not allowed."/>
        <!--- TODO: Verify correct exception type for CF: --->
        <cfcatch type="java.util.zip.zipexception"></cfcatch>
    </cftry>

    <!---
        TODO: Validate any necessary business rules
        (e.g. image not too large, etc)
    --->        

<cfelse>
    <cfthrow message="File Upload Error"/>
</cfif>


<cfif refind('\W',Form.Name)>
    <cfthrow message="Invalid Name specified. Only alphanumerics allowed."/>
</cfif>
<cfif NOT ListFindNoCase('PNG,JPG,GIF',Form.ImageType)>
    <cfthrow message="Invalid FileType specified. Must be PNG/JPG/GIF"/></cfif>
</cfif>

<cffile
    action      = "rename"
    source      = "#UploadedFileName#"
    destination = "#sitepath#storage/bannerImages/#Form.Name#.#Form.ImageType#"
/>

该代码未经测试，并且 - 与您在服务器上运行的所有内容一样，尤其是涉及客户端上传的代码 - 确保您在使用它之前了解它在做什么。
Adobe LiveDocs 和 各种CF博客值得花一些时间消化。