F# 函数的多次退出

Question

我可以在 C++ 中轻松完成此操作（注意：我没有测试其正确性 - 这只是为了说明我想要做什么）：

   const int BadParam = -1;
   const int Success = 0;

   int MyFunc(int param)
   {
      if(param < 0)
      {
         return BadParam;
      }

      //normal processing

      return Success;
   }

但我无法弄清楚如何在 F# 中尽早退出例程。我想要做的是在输入错误时退出该函数，但如果输入正常则继续。我是否遗漏了 F# 的一些基本属性，或者因为我刚刚学习 FP，所以我是否以错误的方式处理问题？ 失败是我唯一的选择吗？

这是我到目前为止所得到的，并且编译正常：

   #light

   module test1

       (* Define how many arguments we're expecting *)
       let maxArgs = 2;;
       (* The indices of the various arguments on the command line *)
       type ProgArguments =
           | SearchString = 0
           | FileSpec = 1;;

       (* Various errorlevels which the app can return and what they indicate *)
       type ProgReturn =
           | Success = 0
           | WrongNumberOfArgumentsPassed = 1;;

       [<EntryPoint>]
       let main (args:string[]) =

           printfn "args.Length is %d" args.Length

           let ProgExitCode = if args.Length <> maxArgs then
                                   printfn "Two arguments must be passed"
                                   int ProgReturn.WrongNumberOfArgumentsPassed
                                   (* Want to exit "main" here but how? *)
                               else
                                   int ProgReturn.Success

           let searchstring, filespec  = args.[int ProgArguments.SearchString],args.[int ProgArguments.FileSpec];

           printfn "searchstring is %s" searchstring
           printfn "filespec is %s" filespec

           ProgExitCode;;

是否有 FP 方法来处理这类事情？

Answer 1

在 F# 中，一切都由表达式组成（而在许多其他语言中，关键构建块是语句）。没有办法提前退出函数，但通常不需要这样做。在 C 中，有一个 if/else 块，其中分支由语句组成。在 F# 中，有一个 if/else 表达式，其中每个分支的计算结果为某种类型的值，整个 if/else 表达式的值为 1分支或其他。

所以这个 C++：

int func(int param) {
  if (param<0)
    return BadParam;
  return Success;
}

在 F# 中看起来像这样：

let func param =
  if (param<0) then
    BadParam
  else
    Success

您的代码处于正确的轨道上，但您可以重构它，将大部分逻辑放在 else 分支中，并将“提前返回”逻辑放在if 分支。

Answer 2

在我看来，匹配表达式类似于 F# 的提前退出，用于调出错误条件并单独处理它们。对于你的例子，我会写：

 [<EntryPoint>]
 let main (args:string[]) =
     printfn "args.Length is %d" args.Length
     match args with
     | [| searchstring; filespace |] -> 
       // much code here ...
       int Success
     | _ -> printfn "Two arguments must be passed"
       int WrongNumberOfArgumentsPassed

这很好地区分了错误情况。一般来说，如果您需要从中途退出，请拆分函数，然后将错误情况放入 match 中。在函数式语言中，函数的大小确实没有限制。

顺便说一句，您使用可区分的联合作为整数常量集有点奇怪。如果您喜欢这个习惯用法，请注意在引用它们时不需要包含类型名称。

Answer 3

首先，正如其他人已经指出的那样，这不是“F# 方式”（嗯，不是 FP 方式，真的）。由于您不处理语句，而只处理表达式，因此实际上没有什么可以突破的。一般来说，这是通过嵌套的 if..then..else 语句链来处理的。

也就是说，我当然可以看到哪里有足够的潜在退出点，长 if..then..else 链可能不是很长可读 - 尤其是在处理某些外部 API 时，这些 API 是为了返回错误代码而不是在失败时抛出异常（例如 Win32 API 或某些 COM 组件），因此您确实需要错误处理代码。如果是这样，在 F# 中执行此操作的具体方法似乎是编写 工作流程。
这是我的第一次尝试：

type BlockFlow<'a> =
    | Return of 'a
    | Continue

type Block() = 
    member this.Zero() = Continue
    member this.Return(x) = Return x
    member this.Delay(f) = f
    member this.Run(f) = 
        match f() with
        | Return x -> x
        | Continue -> failwith "No value returned from block"
    member this.Combine(st, f) =
        match st with
        | Return x -> st
        | Continue -> f()
    member this.While(cf, df) =
        if cf() then
            match df() with
            | Return x -> Return x
            | Continue -> this.While(cf, df)
        else
            Continue
    member this.For(xs : seq<_>, f) =
        use en = xs.GetEnumerator()
        let rec loop () = 
            if en.MoveNext() then
                match f(en.Current) with
                | Return x -> Return x
                | Continue -> loop ()
            else
                Continue
        loop ()
    member this.Using(x, f) = use x' = x in f(x')

let block = Block() 

使用示例：

open System
open System.IO

let n =
    block {
        printfn "Type 'foo' to terminate with 123"
        let s1 = Console.ReadLine()
        if s1 = "foo" then return 123

        printfn "Type 'bar' to terminate with 456"
        let s2 = Console.ReadLine()
        if s2 = "bar" then return 456

        printfn "Copying input, type 'end' to stop, or a number to terminate with that number"
        let s = ref ""
        while (!s <> "end") do
            s := Console.ReadLine()
            let (parsed, n) = Int32.TryParse(!s)
            if parsed then           
                printfn "Dumping numbers from 1 to %d to output.txt" n
                use f = File.CreateText("output.txt") in
                    for i = 1 to n do
                        f.WriteLine(i)
                return n
            printfn "%s" s
    }

printfn "Terminated with: %d" n

如您所见，它有效地定义了所有构造，一旦遇到 return，块的其余部分甚至不会被评估。如果块在没有返回的情况下“结束”流动，您将收到运行时异常（到目前为止，我没有看到任何方法可以在编译时强制执行此操作）。

这有一些限制。首先，工作流程确实不完整 - 它允许您使用 let、use、if、while 和 for 内部，但不是 try..with 或 try..finally。这是可以完成的 - 你需要实现 Block.TryWith 和 Block.TryFinally - 但到目前为止我找不到它们的文档，所以这需要一点一点猜测和更多时间。当我有更多时间时，我可能会回过头来添加它们。

其次，由于工作流程实际上只是一系列函数调用和 lambda 的语法糖 - 特别是，所有代码都在 lambda 中 - 您不能在工作流程中使用 let mutable 。这就是我在上面的示例代码中使用 ref 和 ! 的原因，这是通用的解决方法。

最后，由于所有 lambda 调用，不可避免地会造成性能损失。据推测，F# 比 C# 更擅长优化此类事情（C# 只保留 IL 中的所有内容），并且可以在 IL 级别内联内容并执行其他技巧；但我对此了解不多，因此确切的性能影响（如果有的话）只能通过分析来确定。

Answer 4

与 Pavel 类似的选项，但不需要您自己的工作流构建器，只需将代码块放在 seq 表达式中，并让它 yield 错误消息。然后在表达式之后，您只需调用 FirstOrDefault 即可获取第一条错误消息（或 null）。

由于序列表达式的计算是惰性的，这意味着它只会继续到第一个错误点（假设您从未在序列上调用除 FirstOrDefault 之外的任何内容）。如果没有错误，那么它就会一直运行到最后。因此，如果您这样做，您将能够将收益视为提前回报。

let x = 3.
let y = 0.

let errs = seq {
  if x = 0. then yield "X is Zero"
  printfn "inv x=%f" (1./x)
  if y = 0. then yield "Y is Zero"
  printfn "inv y=%f" (1./y)
  let diff = x - y
  if diff = 0. then yield "Y equals X"
  printfn "inv diff=%f" (1./diff)
}

let firstErr = System.Linq.Enumerable.FirstOrDefault errs

if firstErr = null then
  printfn "All Checks Passed"
else
  printfn "Error %s" firstErr

Answer 5

这个递归斐波那契函数有两个退出点：

let rec fib n =
  if n < 2 then 1 else fib (n-2) + fib(n-1);;
                ^      ^

Answer 6

我自己发现了以下方法。基本上，它生成可能退出的 seq，其中每个退出由 yield 生成，然后仅返回 seq 的 Seq.head首先计算的退出值。我不确定我们是否可以在任何程度上将这种方法称为“功能性”。也不确定这种方法的效率如何以及语言惰性是如何在幕后使用的。也不知道这么多年过去了，作者是否还有必要。但这种方式的一些优点是，代码看起来非常像最初使用非函数式语言时的样子，而仅使用最少的内在功能集。

请参阅下面问题的第一个示例的代码：

let BadParam : int = -1
let Success : int = 0

let MyFunc param =
    seq {
        if (param < 0) then
           printfn " bad param detected "
           yield BadParam

        // normal processing
        printfn "normal processing"
        yield Success
     } |> Seq.head

让我们进行一些测试调用：

printfn "%i" (MyFunc 11)
printfn "%i" (MyFunc -11)

让我们回顾一下输出：

normal processing
0
bad param detected
-1

希望这个想法对那些可能陷入困境的人有所帮助。欢迎对我的上述问题发表任何评论。

Answer 7

我喜欢的是，没有人提到 F# 类型结果？

它由 正式给出

[<Struct>]
type Result<'success,'error> =
   | Ok of 'success
   | Error of 'error

这将满足您的需求，并在处理非 IO 错误以提高性能时使用。

一个很好的例子是解析器函数。

type Parser<'token, 'ret,'error> = Parser of ('token seq -> Result<'ret * 'token seq, 'error>)

let Run (Parser p) = p

let OrParser parser1 parser2 =
    fun input ->
        match Run parser1 input with
        | Ok (item, rest) -> Ok(item, rest)
        | Error _ ->
            match Run parser2 input with
            | Ok (item, rest) -> Ok(item, rest)
            | Error msg -> Error msg
    |> Parser

如果您不熟悉 |> ， 运算符它简单地将左侧（或上面）代码的结果传递给右侧的参数，这里是上面的 lambda 函数

基本情况函数的实现是用户选择的，只要它符合函数类型即可。您可能会注意到，它是任何可能失败的映射（函数）的高度通用函数表示。这包括所有永不失败的功能。

上面的代码是我个人的一些（无代码生成）词法分析器/解析器生成器，仅用于在词法分析器和解析器中构造DFA。代码片段不是我发明的