检查脚本是否具有提升的权限

Question

我想检查 VBscript 运行的上下文是否允许我执行管理任务。

要求：

• 该解决方案应适用于从 Server 2003 开始​​的所有 Windows 操作系统。（这排除了仅检查管理员组中的成员身份的解决方案 - 请记住，有 UAC在 Vista 和 Windows 7 中！）
• 解决方案应该简单。一个 50 LOC 解决方案，用于检查 Windows 组成员身份（当然是递归的，因为用户可能是某个组的成员，而该组是某个组的成员……这是管理员组的成员），然后对 Vista 进行一些额外的检查UAC 并不简单。
• 该解决方案可能有点脏，所以按照 此解决方案 的方式就可以了。
• 它不应该太脏。在我看来，将文件写入 C:\Windows 或写入注册表项太脏了，因为它会修改系统。 （编辑：这可能无论如何都不起作用：例如，在 HTA 中使用 VBScript 时，UAC 重定向就会启动。）

相关问题：https:// /stackoverflow.com/questions/301860（我在那里找到的所有答案（a）忽略UAC问题和（b）都是错误的，因为它们忽略了用户拥有管理权限的可能性，尽管不是直接成员管理员组）

Answer 1

我知道这个帖子很旧并且标记为已回答，但这是一个更简单的方法，一直对我有用。用户 S-1-5-19 是本地 NT 权限，因此访问密钥需要管理员权限。如果通过海拔运行它就可以工作。

Option Explicit 

msgbox isAdmin(), vbOkonly, "Am I an admin?"

Private Function IsAdmin()
    On Error Resume Next
    CreateObject("WScript.Shell").RegRead("HKEY_USERS\S-1-5-19\Environment\TEMP")
    if Err.number = 0 Then 
        IsAdmin = True
    else
        IsAdmin = False
    end if
    Err.Clear
    On Error goto 0
End Function

Answer 2

可能将此（WhoAmI from VBscript）与此（UAC 已打开）。

这是代码，不幸的是 XP 的先决条件是“whoami.exe”，可以在 XP 的资源工具包或支持工具中找到（维基百科） - 我仍然想找到一种没有它的方法。

If UserPerms("Admin") Then
 Message = "Good to go"
Else
 Message = "Non-Admin"
End If

If UACTurnedOn = true Then
 Message = Message & ", UAC Turned On"
Else
 Message = Message & ", UAC Turned Off (Or OS < Vista)"
End If

Wscript.echo Message

Function UserPerms (PermissionQuery)          
 UserPerms = False  ' False unless proven otherwise           
 Dim CheckFor, CmdToRun         

 Select Case Ucase(PermissionQuery)           
 'Setup aliases here           
 Case "ELEVATED"           
   CheckFor =  "S-1-16-12288"           
 Case "ADMIN"           
   CheckFor =  "S-1-5-32-544"           
 Case "ADMINISTRATOR"           
   CheckFor =  "S-1-5-32-544"           
 Case Else                  
   CheckFor = PermissionQuery                  
 End Select           

 CmdToRun = "%comspec% /c whoami /all | findstr /I /C:""" & CheckFor & """"  

 Dim oShell, returnValue        
 Set oShell = CreateObject("WScript.Shell")  
 returnValue = oShell.Run(CmdToRun, 0, true)     
 If returnValue = 0 Then UserPerms = True                   
End Function

Function UACTurnedOn ()
 On Error Resume Next

 Set oShell = CreateObject("WScript.Shell")
 If oShell.RegRead("HKLM\Software\Microsoft\Windows\CurrentVersion\Policies\System\EnableLUA") = 0 Then
      UACTurnedOn = false
 Else
      UACTurnedOn = true
 End If
End Function

Answer 3

上面需要“whoami”的代码来自 CSI-Windows.com/toolkit/ifuserperms 上的 IfUserPerms 脚本。

阅读您的帖子后，我创建了新的脚本代码，用于在 VBS（9 行）和 CMD/BAT（3 行）中使用快速、小型、高效、被动（不更改任何内容）代码检查管理员权限。它还可以与 UAC 配合使用，如果用户未提升权限，则报告错误。

您可以在此处找到代码： http://csi-windows.com/toolkit/csi-isadmin

Answer 4

我添加了两个额外的脚本工具包，它们极大地增强了上面来自 ifuserperms.vbs 的原始代码。

CSI_IsSession.vbs 可以告诉您几乎所有您想了解的有关 UAC 或当前会话的信息该脚本正在运行。

VBScriptUACKit.vbs（使用 CSI_IsSession.vbs）允许您有选择地在脚本中提示 UAC通过重新启动自身。经过设计和调试，可在多种执行场景下工作。

Answer 5

我还有另一个脚本，甚至可以兼容 Windows 98（尽管他们未打补丁的系统在完整性级别之间没有差异）。

将测试文件写入 *%windir%\system32* 是一个相当肮脏的技巧，但出奇地有效。由于它实际上是微软有史以来为防止对系统文件进行授权访问而制定的最重要的规则，因此它可以被视为当时检查系统访问权限（与游戏/应用程序安装所使用的方式相同）的缩影。

Option Explicit

Dim objShell, objFSO, strSystemFolder, strTestFile, isAdmin

Set objShell = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")

strSystemFolder = objShell.ExpandEnvironmentStrings("%windir%") & "\system32"
strTestFile = strSystemFolder & "\test_admin.txt"

isAdmin = False

On Error Resume Next
objFSO.CopyFile WScript.ScriptFullName, strTestFile
If Err.Number = 0 Then
    isAdmin = True
    objFSO.DeleteFile strTestFile
End If
On Error GoTo 0

If isAdmin Then
    MsgBox "Skript has admin rights.", vbInformation, "Status: Elevated"
Else
    MsgBox "Skript has NOT admin rights.", vbExclamation, "Status: Non-Elevated"
End If

该脚本已在以下操作系统上成功测试：

• Windows 98
• Windows 2000
• Windows XP
• Windows 7
• Windows 11

我们必须知道 VBScript 现在被 Microsoft 称为“已弃用”，并且可能会在未来几年默认删除。我不同意这个想法，但这不属于这个主题。

Answer 6

以下是使脚本文件或任何其他文件以管理员身份运行的最快方法：

首先创建您需要执行的任何操作的 VBS 脚本。
就我而言，它是一个注册表编辑 vbs，允许我自动管理登录
然后当机器重新启动时，运行另一个文件以确保
自动管理登录不再启用。

创建文件后，您需要创建一个 cmd 提示符快捷方式。
接下来“右键单击”快捷方式并更改属性，以便它将以管理员身份运行。

像这样粘贴您的文件路径：
D:\WINDOWS\system32\cmd.exe /c "D:\Dump\Scripts\StartUp.vbs"

其中 'C' 表示完成后将关闭
如果您希望它保持打开状态，请使用“K”

希望这对其他人有帮助。