在 Mathematica 中显示重复项

Question

在 Mathematica 中，我有一个列表：

x = {1,2,3,3,4,5,5,6}

如何制作包含重复项的列表？就像：

{3,5}

我一直在查看 Lists as Sets，如果有类似 except 的内容[] 对于列表，所以我可以这样做：（

unique = Union[x]
duplicates = MyExcept[x,unique]

当然，如果 x 有两个以上的重复项 - 例如，{1,2,2,2,3,4,4}，则输出将是 {2,2,4}，但额外的 Union[] 可以解决这个问题。）

但是没有类似的东西（如果我确实很好地理解了那里的所有函数）。

那么，该怎么做呢？

Answer 1

有很多方法可以像这样进行列表提取；这是我想到的第一件事：

Part[Select[Tally@x, Part[#, 2] > 1 &], All, 1]

或者，更易读的片段：

Tally@x
Select[%, Part[#, 2] > 1 &]
Part[%, All, 1]

这分别给出，

{{1, 1}, {2, 1}, {3, 2}, {4, 1}, {5, 2}, {6, 1}}
{{3, 2}, {5, 2}}
{3, 5}

也许你可以想到一种更有效（在时间或代码空间上）的方式 :)

顺便说一句，如果列表未排序，那么您需要先对其运行 Sort 才能正常工作。

Answer 2

以下是一次通过列表即可完成此操作的方法：

collectDups[l_] := Block[{i}, i[n_]:= (i[n] = n; Unevaluated@Sequence[]); i /@ l]

例如：

collectDups[{1, 1, 6, 1, 3, 4, 4, 5, 4, 4, 2, 2}] --> {1, 1, 4, 4, 4, 2}

如果您想要唯一重复项的列表 - {1, 4, 2} - 则将以上内容包装在 DeleteDuplicates，这是对列表的另一次单次传递（Union 效率较低，因为它还会对结果进行排序）。

collectDups[l_] := 
  DeleteDuplicates@Block[{i}, i[n_]:= (i[n] = n; Unevaluated@Sequence[]); i /@ l]

威尔·罗伯逊的解决方案可能更好，因为它更简单，但我认为如果您想寻求更快的速度，这应该会获胜。但如果您关心这一点，您就不会在 Mathematica 中编程！ :)

Answer 3

以下是 Tally 方法的几种更快的变体。

f4 使用了 Carl Woll 和 Oliver Ruebenkoenig 在 MathGroup 上给出的“技巧”。

f2 = Tally@# /. {{_, 1} :> Sequence[], {a_, _} :> a} &;

f3 = Pick[#, Unitize[#2 - 1], 1] & @@ Transpose@Tally@# &;

f4 = # ~Extract~ SparseArray[Unitize[#2 - 1]]["NonzeroPositions"] & @@ Transpose@Tally@# &;

---

速度比较（f1 仅供参考）

a = RandomInteger[100000, 25000];

f1 = Part[Select[Tally@#, Part[#, 2] > 1 &], All, 1] &;

First@Timing@Do[#@a, {50}] & /@ {f1, f2, f3, f4, Tally}

SameQ @@ (#@a &) /@ {f1, f2, f3, f4}

Out[]= {3.188, 1.296, 0.719, 0.375, 0.36}

Out[]= True

令我惊讶的是，f4 相对于纯 Tally 几乎没有任何开销！

Answer 4

使用像 dreeves 这样的解决方案，但只返回每个重复元素的单个实例，有点棘手。一种方法如下：

collectDups1[l_] :=
  Module[{i, j},
    i[n_] := (i[n] := j[n]; Unevaluated@Sequence[]);
    j[n_] := (j[n] = Unevaluated@Sequence[]; n);
    i /@ l];

这与 Will Robertson（IMO 高级）解决方案产生的输出并不完全匹配，因为元素将按照可以确定它们重复的顺序出现在返回的列表中。我不确定它是否真的可以在一次传递中完成，我能想到的所有方法实际上都涉及至少两次传递，尽管一次可能只针对重复的元素。

Answer 5

这是 Robertson 答案的一个版本，它使用 100%“后缀表示法”进行函数调用。

identifyDuplicates[list_List, test_:SameQ] :=
 list //
    Tally[#, test] & //
   Select[#, #[[2]] > 1 &] & //
  Map[#[[1]] &, #] &

Mathematica 的 // 类似于其他语言中方法调用的点。例如，如果这是用 C# / LINQ 风格编写的，则它类似于

list.Tally(test).Where(x => x[2] > 1).Select(x => x[1])

注意，C# 的 Where 类似于 MMA 的 Select，而 C# 的 Select 是就像 MMA 的地图。

编辑：添加了可选的测试函数参数，默认为 SameQ。

编辑：这是一个解决我的评论的版本&报告给定投影仪函数的组中的所有等效项，该投影仪函数生成一个值，如果该值相等，则列表中的元素被视为等效。这本质上会找到比给定大小长的等价类：

reportDuplicateClusters[list_List, projector_: (# &), 
  minimumClusterSize_: 2] :=
 GatherBy[list, projector] //
  Select[#, Length@# >= minimumClusterSize &] &

下面是一个示例，用于检查其第一个元素上的整数对，如果它们的第一个元素相等，则认为两对相等

reportDuplicateClusters[RandomInteger[10, {10, 2}], #[[1]] &]

Answer 6

该线程似乎很旧，但我必须自己解决这个问题。

这有点粗糙，但是这样做可以吗？

Union[Select[Table[If[tt[[n]] == tt[[n + 1]], tt[[n]], ""], {n, Length[tt] - 1}], IntegerQ]]

Answer 7

另一种短期的可能性是

Last /@ Select[Gather[x], Length[#] > 1 &]

Answer 8

给定一个列表 A，
获取 B 中的非重复值
B = 删除重复项[A]
获取 C 中的重复值
C = 求补 [A,B]
从 D 中的重复列表中获取非重复值
D = DeleteDuplicates[C]

因此，对于您的示例：
A = 1, 2, 2, 2, 3, 4, 4
B = 1, 2, 3, 4
C = 2, 2, 4
D = 2, 4

所以你的答案将是DeleteDuplicates[Complement[x,DeleteDuplicates[x]]]，其中 x 是你的列表。我不懂数学，所以这里的语法可能完美也可能不完美。只需查看您链接到的页面上的文档即可。