groovy 是否有一种简单的方法来获取不带扩展名的文件名？

Question

假设我有这样的内容：

new File("test").eachFile() { file->  
println file.getName()  
}

这将打印 test 目录中每个文件的完整文件名。有没有一种 Groovy 方法可以获取不带任何扩展名的文件名？ （或者我又回到了正则表达式领域？）

Answer 1

我相信最好的方法是：

file.name.lastIndexOf('.').with {it != -1 ? file.name[0..<it] : file.name}

或者使用一个简单的正则表达式：

file.name.replaceFirst(~/\.[^\.]+$/, '')

还有一个用于这种目的的 apache commons-io java lib，如果您使用 maven，您可以轻松依赖它：

org.apache.commons.io.FilenameUtils.getBaseName(file.name)

Answer 2

最干净的方式。

String fileWithoutExt = file.name.take(file.name.lastIndexOf('.'))

Answer 3

最简单的方法是：

'file.name.with.dots.tgz' - ~/\.\w+$/​​​​​​​​​​​​​​​​​​​​​​​​​​​​​​​​​​​​

结果是：

file.name.with.dots

Answer 4

new File("test").eachFile() { file->  
    println file.getName().split("\\.")[0]
}

这对于以下文件名非常有效：
foo, foo.bar

但是如果你有一个文件 foo.bar.jar，那么上面的代码会打印出： foo
如果您希望它打印出 foo.bar ，那么下面的代码可以实现这一点。

new File("test").eachFile() { file->  
    def names = (file.name.split("\\.")
    def name = names.size() > 1 ? (names - names[-1]).join('.') : names[0]
    println name
}

Answer 5

FilenameUtils 类是 apache commons io 包的一部分，有一个强大的解决方案。用法示例：

import org.apache.commons.io.FilenameUtils

String filename = '/tmp/hello-world.txt'
def fileWithoutExt = FilenameUtils.removeExtension(filename)

这不是常规方法，但如果您需要支持大量边缘情况，这可能会有所帮助。

Answer 6

也许不像你想象的那么容易，但工作：

new File("test").eachFile { 
  println it.name.lastIndexOf('.') >= 0 ? 
     it.name[0 .. it.name.lastIndexOf('.')-1] : 
     it.name 
  }

Answer 7

正如评论中提到的，文件名结尾 &延期开始取决于具体情况。在我的情况下，我需要获取以下类型文件的基本名称（没有路径的文件，和没有扩展名）：{ foo.zip, bar/foo.tgz, foo.tar.gz } =>;都需要生成“foo”作为没有扩展名的文件名。 （大多数解决方案，给定 foo.tar.gz 都会生成 foo.tar。）

这是一个（明显的）解决方案，它将为您提供第一个“.”之前的所有内容；或者，您可以分段获取整个扩展名，或者（在本例中）作为单个剩余部分（将文件名拆分为 2 部分）。 （注意：虽然与手头的任务无关，但我也通过调用 file.name 删除了路径。）

file=new File("temp/foo.tar.gz")
file.name.split("\\.", 2)[0]    // => return "foo" at [0], and "tar.gz" at [1]

Answer 8

您可以更好地使用正则表达式。
像下面这样的函数就可以解决这个问题：

def getExtensionFromFilename(filename) {
  def returned_value = ""
  m = (filename =~ /(\.[^\.]*)$/)
  if (m.size()>0) returned_value = ((m[0][0].size()>0) ? m[0][0].substring(1).trim().toLowerCase() : "");
  return returned_value
}

Answer 9

注意

import java.io.File;

def fileNames    = [ "/a/b.c/first.txt", 
                     "/b/c/second",
                     "c:\\a\\b.c\\third...",
                     "c:\\a\b\\c\\.text"
                   ]

def fileSeparator = "";

fileNames.each { 
    // You can keep the below code outside of this loop. Since my example
    // contains both windows and unix file structure, I am doing this inside the loop.
    fileSeparator= "\\" + File.separator;
    if (!it.contains(File.separator)) {
        fileSeparator    =  "\\/"
    }

    println "File extension is : ${it.find(/((?<=\.)[^\.${fileSeparator}]+)$/)}"
    it    =  it.replaceAll(/(\.([^\.${fileSeparator}]+)?)$/,"")

    println "Filename is ${it}" 
}

下面的一些解决方案（使用 apache 库的解决方案除外）不适用于此示例 - c:/test.me/firstfile

如果我尝试查找上述条目的扩展名，我会get ".me/firstfile" - :(

更好的方法是查找最后一次出现的 File.separator（如果存在），然后查找文件名或扩展名。

注意：
（下面有一个小技巧。对于 Windows，文件分隔符是 \。但这是正则表达式中的特殊字符，因此当我们在正则表达式中使用包含 File.separator 的变量时，我必须对其进行转义。这就是我这样做的原因：

def fileSeparator= "\\" + File.separator;

希望它有意义:)

尝试一下：

import java.io.File;

String strFilename     =  "C:\\first.1\\second.txt";
// Few other flavors 
// strFilename = "/dd/dddd/2.dd/dio/dkljlds.dd"

def fileSeparator= "\\" + File.separator;
if (!strFilename.contains(File.separator)) {
    fileSeparator    =  "\\/"
}

def fileExtension = "";
(strFilename    =~ /((?<=\.)[^\.${fileSeparator}]+)$/).each { match,  extension -> fileExtension = extension }
println "Extension is:$fileExtension"

Answer 10

// Create an instance of a file (note the path is several levels deep)
File file = new File('/tmp/whatever/certificate.crt')

// To get the single fileName without the path (but with EXTENSION! so not answering the question of the author. Sorry for that...)
String fileName = file.parentFile.toURI().relativize(file.toURI()).getPath()