LINQ to XML 和独特的自定义类

Question

我有一个非常有趣的 LINQ 问题。我有一个文档，我正在尝试过滤结果，但为了过滤，我匹配来自 XML 一个元素的 REGEX 结果。

我有以下内容，使用 LINQ to XML 来获取我正在查找的单个数据。

Dim oDocument As XDocument
oDocument = XDocument.Load("test.xml")
Dim results = (From x In oDocument.Descendants.Elements("ROW") _
   Select New With {.ApplicationName = GetApplicationName(x.Element("Message")), _
    .EventId = x.Element("EventId")}).Distinct

但是，.Distinct 并没有达到我想要的效果，它仍然显示“ApplicationName”和“EventId”的所有组合。

我最终需要的是一个不同的结果列表，位于一个新对象中，其中包含应用程序名称和 XML 中的事件 ID。

“GetAPplicationName”是一个解析值以查找正则表达式匹配的函数。

有什么指点吗？

示例 XML

<ROOT>
  <ROW>
    <EventId>1</EventId>
    <CreatedTimestamp>2009-10-28</CreatedTimestamp>
    <Message>There is a bunch
    of 
  garbled
inforamtion here and I'm trying to parse out a value 
Virtual Path: /MyPath then it continues on with more junk after the
message, including extra stuff
    </Message>
    <!--Other elements removed for brevity -->
  </ROW>
  <ROW>
    <EventId>1</EventId>
    <CreatedTimestamp>2009-10-28</CreatedTimestamp>
    <Message>
      There is a bunch
      of
      garbled
      inforamtion here and I'm trying to parse out a value
      Virtual Path: /MyPath then it continues on with more junk after the
      message, including extra stuff
    </Message>
    <!--Other elements removed for brevity -->
  </ROW>
</ROOT>

从这里我想要不同的 /MyPath 和 EventId（在本例中，1 个条目带有 /MyPath 和 1.My

GetApplicationNameMethod，在此示例中将返回 /MyPath

Answer 1

艾哈迈德的回答是正确的，我投了赞成票。不过，我只是想指出 LINQ to XML 查询的替代 VB.NET 特定语法。

Dim results = From x In doc...<ROW> _
   Select New EventInfo With {.ApplicationName = GetApplicationName(x.<Message>.Value, _
    .EventId = x.<EventId>.Value}

这会返回相同的结果，但如果您导入 xmlns，那么您将通过这种方式获得元素名称的 IntelliSense。

以下文章介绍了如何在 VB.NET 中获取 XML IntelliSense：

http:// msdn.microsoft.com/en-us/library/bb531325.aspx

Answer 2

Distinct 不知道如何比较您的项目，因此它返回所有未过滤的项目。您应该使用实现 IEqualityComparer 的独特重载。这将允许您比较 ApplicationName 和 EventId 属性以确定相等性。然而，这样做意味着拥有一个真正的类，而不是一个匿名类型。该文档演示了如何以易于理解的方式实现这一目标。

编辑：我能够将您的示例与 IEqualityComparer 和 EventInfo 类一起使用。我添加了自己的 GetApplicationName 实现来测试。

    Dim results = (From x In doc.Descendants.Elements("ROW") _
       Select New EventInfo With {.ApplicationName = GetApplicationName(x.Element("Message")), _
        .EventId = x.Element("EventId")})

    Console.WriteLine("Total: {0}", results.Count)
    Console.WriteLine("Distinct Total: {0}", results.Distinct.Count)
    Console.WriteLine("Distinct (w/comparer) Total: {0}", results.Distinct(New EventInfoComparer()).Count)

输出：

Total: 2
Distinct Total: 2
Distinct (w/comparer) Total: 1

其余代码：

' EventInfo class and comparer
Private Function GetApplicationName(ByVal element As XElement)
    Return Regex.Match(element.Value, "Virtual\sPath:\s/(\w+)").Groups(1).Value
End Function

Public Class EventInfo
    Private _applicationName As String
    Public Property ApplicationName() As String
        Get
            Return _applicationName
        End Get
        Set(ByVal value As String)
            _applicationName = value
        End Set
    End Property

    Private _eventId As Integer
    Public Property EventId() As Integer
        Get
            Return _eventId
        End Get
        Set(ByVal value As Integer)
            _eventId = value
        End Set
    End Property
End Class

Public Class EventInfoComparer
    Implements IEqualityComparer(Of EventInfo)

    Public Function Equals1(ByVal x As EventInfo, ByVal y As EventInfo) As Boolean _
        Implements IEqualityComparer(Of EventInfo).Equals

        ' Check whether the compared objects reference the same data.
        If x Is y Then Return True

        ' Check whether any of the compared objects is null.
        If x Is Nothing OrElse y Is Nothing Then Return False

        ' Check whether the EventInfos' properties are equal.
        Return (x.ApplicationName = y.ApplicationName) AndAlso (x.EventId = y.EventId)
    End Function

    Public Function GetHashCode1(ByVal eventInfo As EventInfo) As Integer _
        Implements IEqualityComparer(Of EventInfo).GetHashCode

        ' Check whether the object is null.
        If eventInfo Is Nothing Then Return 0

        ' Get the hash code for the ApplicationName field if it is not null.
        Dim hashEventInfoAppName = _
            If(eventInfo.ApplicationName Is Nothing, 0, eventInfo.ApplicationName.GetHashCode())

        ' Get the hash code for the EventId field.
        Dim hashEventInfoId = eventInfo.EventId.GetHashCode()

        ' Calculate the hash code for the EventInfo.
        Return hashEventInfoAppName Xor hashEventInfoId
    End Function
End Class

Answer 3

我以前从未注意到这一点，但 VB 的匿名类型似乎不会覆盖 Equals() 和 GetHashcode()。因此，Distinct() 正在检查引用相等性。最简单的解决方法是构建您自己的实现 IEquatable 的类。