Excel VBA 中的范围数组

Question

好吧，我一直在努力处理一小段代码，似乎无法绕过它...... 我试图从一系列单元格中获取一个数组，但该数组显示为 1 个元素宽。
这是代码：

Dim item As Variant
MsgBox Range("D19:H19").Count    
item = Range("D19:H19").Value
MsgBox LBound(item) & " " & UBound(item)   

根据我的理解，项目应该包含一个二维数组......但是我得到以下结果 第一个 MsgBox 打印 5 第二个 MsgBox 打印 1 1

出了什么问题？

Answer 1

问题出在 LBound 和 UBound

jtolle 关于 LBound 和 UBound 的说法是正确的。

LBound(item, 2)

UBound(item, 2)

但是，项目不得作为数组变暗（您将收到错误）。

我想这就是你想要的

Dim item As Variant
MsgBox Range("D19:H19").Count
item = Range("D19:H19").Value

MsgBox LBound(item, 2) & " " & UBound(item, 2)

For i = LBound(item, 2) To UBound(item, 2)
  MsgBox item(1, i)
Next

Answer 2

您的项目应按预期包含一个二维数组。如果您在代码中设置断点并查看 VBA 编辑器中的小“Locals”窗口，您应该会看到这一点。您对 LBound 和 UBound 的调用将获得第一维的边界。如果您调用 Lbound(item,2) 和 UBound(item,2)，您应该得到您期望的 1 和 5。

编辑：
也就是说，一旦完成分配，item 看起来就像您可以这样声明的东西：

Dim item(1 to 1, 1 to 5)

VBA 编程的祸根之一是数组可以具有任意下限。所以你的所有代码都需要意识到这一点。

Answer 3

这是正确的。即使您选择一组单元格，您仍然可以选择从数组中选择一个单元格（例如使用 Tab 键浏览该数组的项目）

.Value

只能获取当前单个选定单元格的内容。

如果您想要枚举数组，您可以调用 Range 对象的 .Cells() 方法

假设 D19 到 H19 包含“a”到“e” " 分别调用

Range("D19:H19").Cells(2)

会返回 "b"。请注意，这是一个基于一的数组，并且可以是二维的。 Cells() 最多采用 2 个参数来指定距选区原点的内部偏移量。

希望能澄清...问候

Answer 4

试试这个：

Dim item As Variant
MsgBox Range("D19:H19").Count
item = Application.Transpose(Range("D19:H19").Value)
MsgBox LBound(item) & " " & UBound(item)

Answer 5

例如，如果您想要一个一维数组，将其连接到 IN 子句，您应该转置您的范围。
我发现你必须为一行转置两次，为一列数据转置一次，如下所示：

Dim rngRow As Range, rngColumn As Range

Set rngRow = Sheets(1).Range("A1", "Z1")
Set rngColumn = Sheets(1).Range("A1", "A20")

Dim arrRowValues, arrColValues
arrRowValues = WorksheetFunction.Transpose(WorksheetFunction.Transpose(rngRow))
arrColValues = WorksheetFunction.Transpose(rngColumn)

Dim numList As String, stringList As String
numList = Join(arrRowValues, ",")
stringList = "'" & Join(arrColValues, "','") & "'"

值得一试。