使用标准 Acrobat 以编程方式合并 PDF 文件？

Question

SO 和其他地方有很多关于使用非 Adob​​e 产品以编程方式组合 PDF 文件的建议。

有没有办法（相当容易地）使用我的 Adob​​e Acrobat Standard（不是 Reader）的付费副本以编程方式将两个或多个 PDF 文件合并为一个新的 PDF 文件（我知道可以通过合并 -> 多个文件手动完成） ？

更喜欢命令（例如，复制 file1.pdf file2.pdf合并.pdf），但愿意诉诸VBA。

感谢您的任何想法！

Answer 1

Sub MergePDFs(nDocs As Integer, BaseFileName As String)

    Dim AcroApp As Acrobat.CAcroApp
    Dim iDoc As Integer

    Dim BaseDocument As Acrobat.CAcroPDDoc
    Dim PartDocument As Acrobat.CAcroPDDoc

    Dim numPages As Integer

    Set AcroApp = CreateObject("AcroExch.App")

    Set BaseDocument = CreateObject("AcroExch.PDDoc")
    Set PartDocument = CreateObject("AcroExch.PDDoc")


    BaseDocument.Open (ActiveWorkbook.Path & "\" & BaseFileName & "_" & 1 & ".pdf")
    For iDoc = 2 To nDocs
        PartDocument.Open (ActiveWorkbook.Path & "\" & BaseFileName & "_" & iDoc & ".pdf")
        numPages = BaseDocument.GetNumPages()

        ' Insert the pages of Part after the end of Base
        If BaseDocument.InsertPages(numPages - 1, PartDocument, 0, PartDocument.GetNumPages(), True) = False Then
            MsgBox "Cannot insert pages"
        End If
        PartDocument.Close
    Next iDoc
    If BaseDocument.Save(PDSaveFull, ActiveWorkbook.Path & "\" & BaseFileName & ".pdf") = False Then
        MsgBox "Cannot save the modified document"
    Else
        ' Remove intermediate documents
        For iDoc = 1 To nDocs
            Kill ActiveWorkbook.Path & "\" & BaseFileName & "_" & iDoc & ".pdf"
        Next iDoc
    End If
    BaseDocument.Close

    AcroApp.Exit
    Set AcroApp = Nothing
    Set BaseDocument = Nothing
    Set PartDocument = Nothing

End Sub

Answer 2

Acrobat 没有 VBA。 VBA 是 Microsoft 的东西（并且显然很快就会从我读到的内容中消失[编辑：删除该内容；显然它在 Office 2010 中仍然存在并且运行良好]）。

Acrobat SDK 将允许您自动化 Acrobat 并执行您想做的事情，但它不适合胆小的人。使用您在其他地方读到的免费解决方案之一可能会更容易（无论如何是短期的）。