模仿“IN”操作员

Question

如何才能实现：

if X in (1,2,3) then

而不是：

if x=1 or x=2 or x=3 then

换句话说，如何才能最好地模仿 Excel 的 VBA 中的 IN 运算符？

Answer 1

我认为没有一个非常优雅的解决方案。

但是，您可以尝试：

If Not IsError(Application.Match(x, Array("Me", "You", "Dog", "Boo"), False)) Then

或者您可以编写自己的函数：

Function ISIN(x, StringSetElementsAsArray)
    ISIN = InStr(1, Join(StringSetElementsAsArray, Chr(0)), _
    x, vbTextCompare) > 0
End Function

Sub testIt()
    Dim x As String
    x = "Dog"
    MsgBox ISIN(x, Array("Me", "You", "Dog", "Boo"))
End Sub

Answer 2

您还可以尝试使用 CASE 语句代替 IF

Select Case X

 Case 1 To 3   
  ' Code to do something
 Case 4, 5, 6
  ' Code to do something
 Case 7
  ' Code to do something
 Case Else  
  ' More code or do nothing

End Select

Answer 3

最快的方法：

这是一种比其他答案任何更快、更紧凑的方法，并且适用于数字或文本值：

Function IsIn(valCheck, valList As String) As Boolean  
    IsIn = Not InStr("," & valList & ",", "," & valCheck & ",") = 0
End Function

---

示例：

将 IsIn 与数值一起使用：

Sub demo_Number()
    Const x = 2
    If IsIn(x, "1,2,3") Then
        Debug.Print "Value " & x & " was Found!"
    Else
        Debug.Print "Value " & x & " was not Found."
    End If
End Sub

将 IsIn 与字符串值一起使用：

Sub demo_Text()
    Const x = "Dog"
    If IsIn(x, "Me,You,Dog,Boo") Then
        Debug.Print "Value " & x & " was Found!"
    Else
        Debug.Print "Value " & x & " was not Found."
    End If
End Sub

---

速度比较:

为了比较速度，我从接受的答案运行了测试 100,000 次：

• 0.406 秒（最快） 此函数（使用 InStr):
• 1.828 秒（慢 450%） 已接受 使用“ISIN”函数回答
• 1.799 秒（慢 440%） 用 freeVBcode 中的“IsInArray”回答
• 0.838 秒（慢 206%） 使用修改后的“IsInArray”函数回答

我没有包含更长的答案< /a> 使用 SELECT..CASE ，因为与“if x=1 or x=2 or x=3 那么”。

Answer 4

你试过吗

eval("3 in(1,2,3,4,5)")

Answer 5

据我所知，没有一个。

我通常使用自制的 InArray() 函数，例如 http://www 中的函数.freevbcode.com/ShowCode.asp?ID=1675

您还可以制作一个迭代数组而不是连接的版本（如果这更适合您的数据类型）。

Answer 6

如果不编写自己的函数，它就无法工作。请注意，@Kredns 接受的解决方案可能无法按预期适用于所有类型的对象，因为它们被强制为字符串（这也可能引发类型不匹配错误）。

该解决方案应该（希望）处理所有类型的数据（至少在 Excel 365 中，不确定早期版本）：

Function IsIn(x As Variant, list As Variant) As Boolean
    ' Checks whether list (Array) contains the element x
    IsIn = False
    For Each element In list
        If x = element Then IsIn = True
    Next element
End Function

Answer 7

dim x, y
x = 2
y = Array(1, 2, 3)

For i = 0 To 2
If x = y(i) Then
'your code comes here
Exit For
End If
Next i

Answer 8

我现在写了...

Public Function IsInArray(FindValue As Variant, ParamArray arrEmailAttachment()) As Boolean

Dim element As Variant

For Each element In arrEmailAttachment
    If element = FindValue Then
        IsInArray = True
        Exit Function
    End If
Next element

IsInArray = False

End Function