有没有办法刷新 Oracle 中 PL/SQL 的输出？

Question

我有一个从 shell 脚本中调用的 SQL 脚本，需要很长时间才能运行。它当前在不同点包含 dbms_output.put_line 语句。这些打印语句的输出会出现在日志文件中，但仅在脚本完成后才会出现。

有什么方法可以确保脚本运行时输出出现在日志文件中？

Answer 1

并不真地。 DBMS_OUTPUT 的工作方式是这样的：您的 PL/SQL 块在数据库服务器上执行，不与客户端交互。因此，当您调用 PUT_LINE 时，它只是将该文本放入服务器内存中的缓冲区中。当您的 PL/SQL 块完成时，控制权将返回给客户端（在本例中我假设是 SQLPlus）；此时，客户端通过调用 GET_LINE 从缓冲区中获取文本并显示它。

因此，使输出更频繁地出现在日志文件中的唯一方法是将大型 PL/SQL 块分解为多个较小的块，以便更频繁地将控制权返回给客户端。这可能不切实际，具体取决于您的代码正在执行的操作。

其他替代方法是使用 UTL_FILE 写入文本文件（可以随时刷新该文件），或者使用自主事务过程将调试语句插入数据库表中并在每条语句后提交。

Answer 2

如果可能的话，您应该用您自己的函数替换对 dbms_output.put_line 的调用。

以下是此函数的代码WRITE_LOG - 如果您希望能够在 2 个日志记录解决方案之间进行选择：

将日志写入表在自主事务

CREATE OR REPLACE PROCEDURE to_dbg_table(p_log varchar2)
  -- table mode: 
  -- requires
  -- CREATE TABLE dbg (u varchar2(200)   --- username
  --                 , d timestamp       --- date
  --                 , l varchar2(4000)  --- log 
  -- );
AS
   pragma autonomous_transaction;
BEGIN
  insert into dbg(u, d, l) values (user, sysdate, p_log);
  commit;
END to_dbg_table;
/

或直接写入托管数据库的数据库服务器

这使用Oracle 目录 TMP_DIR

CREATE OR REPLACE PROCEDURE to_dbg_file(p_fname varchar2, p_log varchar2)
  -- file mode: 
  -- requires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
  l_file utl_file.file_type;
BEGIN
  l_file := utl_file.fopen('TMP_DIR', p_fname, 'A');
  utl_file.put_line(l_file, p_log);
  utl_file.fflush(l_file);
  utl_file.fclose(l_file);
END to_dbg_file;
/

WRITE_LOG

然后WRITE_LOG< /code>程序可以在两种用途之间切换，或者被停用以避免性能损失（g_DEBUG:=FALSE）。

CREATE OR REPLACE PROCEDURE write_log(p_log varchar2) AS
  -- g_DEBUG can be set as a package variable defaulted to FALSE
  -- then change it when debugging is required
  g_DEBUG boolean := true;
  -- the log file name can be set with several methods...
  g_logfname varchar2(32767) := 'my_output.log';
  -- choose between 2 logging solutions:
  -- file mode: 
  g_TYPE varchar2(7):= 'file';
  -- table mode: 
  --g_TYPE varchar2(7):= 'table';
  -----------------------------------------------------------------
BEGIN
  if g_DEBUG then
    if g_TYPE='file' then
      to_dbg_file(g_logfname, p_log);
    elsif g_TYPE='table' then
      to_dbg_table(p_log);
    end if;
  end if;  
END write_log;
/

以下是如何测试上述内容：

1) 从 SQLPLUS 启动此（文件模式）：

BEGIN
  write_log('this is a test');
  for i in 1..100 loop
    DBMS_LOCK.sleep(1);
    write_log('iter=' || i);
  end loop;
  write_log('test complete');
END;
/

2) 在数据库服务器上，打开 shell 并

    tail -f -n500 /directory/where/oracle/can/write/on/DB_server/my_output.log

Answer 3

两种替代方案：

1. 您可以使用自治事务将日志记录详细信息插入日志记录表中。您可以在另一个 SQLPLUS/Toad/sql Developer 等会话中查询此日志记录表。您必须使用自治事务才能提交日志记录，而不会干扰主 sql 脚本中的事务处理。

2. 另一种选择是使用返回日志信息的管道函数。请参阅此处的示例： http://berxblog.blogspot.com /2009/01/pipelined-function-vs-dbmsoutput.html 当您使用管道函数时，您不必使用另一个 SQLPLUS/Toad/sql 开发人员等...会话。

Answer 4

当调用过程DBMS_OUTPUT.get_line时，读取DBMS_OUTPUT的缓冲区。如果您的客户端应用程序是 SQL*Plus，则意味着只有在过程完成后才会刷新它。

您可以应用 此 SO 将 DBMS_OUTPUT 缓冲区写入文件。

Answer 5

使用dbms_application_info()设置会话元数据MODULE和/或ACTION。
通过 OEM 进行监控，例如：

Module: ArchiveData
Action: xxx of xxxx

Answer 6

如果您可以从 PL/SQL 环境访问系统 shell，您可以调用 netcat：

 BEGIN RUN_SHELL('echo "'||p_msg||'" | nc '||p_host||' '||p_port||' -w 5'); END;

p_msg - 是一条日志消息
v_host 是运行 python 脚本的主机，它从端口 v_port 上的套接字读取数据。

当我为实时 shell 编写 aplogr 时，我使用了这种设计pl/sql 日志监控。