有没有办法检测您何时到达 SAS 数据步骤中的最后一个观察结果？

Question

有没有办法在运行时检查 SAS 数据集中有多少个观测值，或者检测何时到达 DATA 步骤中的最后一个观测值？

对于这个看似简单的问题，我似乎无法在网络上找到任何内容。谢谢！

Answer 1

set 语句的 nobs= 选项可以为您提供观察值的数量。编译数据步骤时，将扫描输入数据集的标头部分，因此您甚至不必执行 set 语句即可获取观测值的数量。例如，以下报告按预期报告 2：

/* a test data set with two observations and no vars */
data two;
  output;
  output;
run;

data _null_;
  if 0 then set two nobs=nobs;
  put nobs=;
run;
/* on log
nobs=2
*/

end= 选项在读入最后一个观察值（对于 set 语句）时设置一个标志。

一个 SAS 数据集，但是，可以是 SAS 数据文件或 SAS 视图。在后者的情况下，观察的数量在编译时或执行时可能是未知的。

data subclass/view=subclass;
  set sashelp.class;
  where sex = symget("sex");
run;

%let sex=F;
data girls;
  set subclass end=end nobs=nobs;
  put name= nobs= end=;
run;
/* on log
Name=Alice nobs=9.0071993E15 end=0
Name=Barbara nobs=9.0071993E15 end=0
Name=Carol nobs=9.0071993E15 end=0
Name=Jane nobs=9.0071993E15 end=0
Name=Janet nobs=9.0071993E15 end=0
Name=Joyce nobs=9.0071993E15 end=0
Name=Judy nobs=9.0071993E15 end=0
Name=Louise nobs=9.0071993E15 end=0
Name=Mary nobs=9.0071993E15 end=1
*/

Answer 2

您还可以使用%sysfunc(attrn( dataset, nlobs))，尽管它仅限于 SAS 数据集（即不是数据视图）。该宏归功于这篇 SUGI 论文，其中还提供了有关以下方面的重要信息：良好的宏观设计。

您可以获得 SAS 数据集上的各种其他字符和数字信息。

请参阅有关 attrn 和 < a href="http://support.sas.com/documentation/cdl/en/lrdict/61724/HTML/default/a000147794.htm" rel="noreferrer">attrc。

%macro numobs (data=&syslast ) ;
/* --------------------------------------------
Return number of obs as a function
--------------------------------------------
*/
%local dsid nobs rc;
%let data = &data ; /* force evaluation of &SYSLAST */
%let dsid=%sysfunc(open(&data));
%if &dsid > 0 %then
%do ;
   %let nobs=%sysfunc(attrn(&dsid,nlobs));
   %let rc=%sysfunc(close(&dsid));
%end ;
%else
   %let nobs = -1 ;
&nobs
%mend numobs;

Answer 3

查找 SAS 数据集中的观测值数量：

proc sql noprint;
  select count(*) into: nobs
  from sashelp.class
  ;
quit;

data _null_;
  put "&nobs";
run;

SQL 部分计算观测值的数量，并将该数字存储在名为“nobs”的宏变量中。
数据步骤放置要显示的数字，但您可以像使用其他变量一样使用宏变量。

处理最后一个观察时执行特定操作：

data _null_;
  set sashelp.class end=eof;
  if eof then do;
     put name= _n_=;
  end;
run;

“set”语句的“end”选项定义一个变量（此处“eof”表示文件结束），当处理最后一个观察时，该变量设置为 1。然后，您可以测试变量的值，并在其值为 1 时执行操作。有关详细信息，请参阅“set”语句的文档。

Answer 4

data hold;   
  set input_data end=last;    
    .    
    .   
    .   
  if last then do;   
    .   
    .   
    .   
  end;  
run;