在 vb.net 中进行数学计算，就像在 javascript 中进行 Eval 一样

Question

有没有什么方法可以解析 vb.net 中的字符串（例如内置方法），可以像 Eval 一样进行数学运算？例如，3+(7/3.5) 作为字符串将返回 2。

我并不是要求您为我编写此代码，我只是想知道是否有内置方法可以做到这个，如果没有我会自己编码。

我可以打赌它无法自行解析像 Sin(90) 这样的东西，而且我知道它需要被 Math.Sin(90) 替换。

如果有内置方法，如何使用它？

Answer 1

通过使用 DataTable.Compute 方法。显然，这并不健壮（功能有限），并且出于此目的滥用 DataTable 感觉很黑客，但我想我会添加到当前的答案中。

示例：

var result = new DataTable().Compute("3+(7/3.5)", null); // 5

“Sin(90)”不适用于此方法。请参阅 DataColumn.Expression 属性页有关受支持函数的列表，特别是在“聚合”部分下。

使用 System.CodeDom 命名空间是一种选择。

一些有用的链接：

• CodeDom 计算器
• 使用 CodeDom 计算数学表达式
• 相关问题：.NET 中有字符串数学评估器吗？

---

编辑： 在此发表您的评论是一种演示用等效的 Math 类方法替换三角函数的方法。

C#

string expression = "(Sin(0) + Cos(0)+Tan(0)) * 10";
string updatedExpression = Regex.Replace(expression, @"(?<func>Sin|Cos|Tan)\((?<arg>.*?)\)", match =>
            match.Groups["func"].Value == "Sin" ? Math.Sin(Int32.Parse(match.Groups["arg"].Value)).ToString() :
            match.Groups["func"].Value == "Cos" ? Math.Cos(Int32.Parse(match.Groups["arg"].Value)).ToString() :
            Math.Tan(Int32.Parse(match.Groups["arg"].Value)).ToString()
        );
var result = new DataTable().Compute(updatedExpression, null); // 10

VB.NET

Dim expression As String = "(Sin(0) + Cos(0)+Tan(0)) * 10"
Dim updatedExpression As String = Regex.Replace(expression, "(?<func>Sin|Cos|Tan)\((?<arg>.*?)\)", Function(match As Match) _
        If(match.Groups("func").Value = "Sin", Math.Sin(Int32.Parse(match.Groups("arg").Value)).ToString(), _
        If(match.Groups("func").Value = "Cos", Math.Cos(Int32.Parse(match.Groups("arg").Value)).ToString(), _
        Math.Tan(Int32.Parse(match.Groups("arg").Value)).ToString())) _
        )
Dim result = New DataTable().Compute(updatedExpression, Nothing)

但请注意，您需要知道“arg”组的内容。我知道它们是整数，所以我对它们使用了 Int32.Parse 。如果它们是项目的组合，那么这种简单的方法将不起作用。我怀疑如果解决方案因更多不受支持的函数调用而变得过于复杂，您将不断需要对解决方案进行创可贴，在这种情况下，CodeDom 方法或其他方法可能更合适。

Answer 2

这是一种我在其他地方没有提到过的计算表达式的方法：使用 WebBrowser 控件和 JavaScript 的 eval()：

Option Strict On

Imports System.Security.Permissions

<PermissionSet(SecurityAction.Demand, Name:="FullTrust")> _
<System.Runtime.InteropServices.ComVisibleAttribute(True)>
Public Class Form1
    Dim browser As New WebBrowser

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        browser.ObjectForScripting = Me
        'browser.ScriptErrorsSuppressed = True
        browser.DocumentText = "<script>function evalIt(x) { return eval(x); }</script>"
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        Dim result = browser.Document.InvokeScript("evalIt", New String() {"3+4*5"})
        If result IsNot Nothing Then
            MessageBox.Show(result.ToString())     '23
        End If
    End Sub
End Class

Answer 3

这篇 CodeProject 文章可能会解决这个问题：

用 VB.NET 编写的表达式计算器
http://www.codeproject.com/KB/vb/expression_evaluator.aspx

还有这个：
http://www.dotnetspider.com/resources/ 2518-数学表达式-表达式-求值-VB.aspx

Answer 4

一种方法是使用 CodeDom 命名空间来编译它并使用反射执行它。我不知道，可能没有那么高效。

Answer 5

有点晚了，但这正是您想要的（确保解析输入以确保其中没有类似“something + vbcrlf + exec“format c:””的语句）：

用法：

MessageBox.Show(COR.Tools.EvalProvider.Eval("return 8-3*2").ToString())

 
班级：

'Imports Microsoft.VisualBasic
Imports System


Namespace COR.Tools


Public Class EvalProvider


    Public Shared Function Eval(ByVal vbCode As String) As Object
        Dim c As VBCodeProvider = New VBCodeProvider
        Dim icc As System.CodeDom.Compiler.ICodeCompiler = c.CreateCompiler()
        Dim cp As System.CodeDom.Compiler.CompilerParameters = New System.CodeDom.Compiler.CompilerParameters

        cp.ReferencedAssemblies.Add("System.dll")
        cp.ReferencedAssemblies.Add("System.xml.dll")
        cp.ReferencedAssemblies.Add("System.data.dll")
        ' Sample code for adding your own referenced assemblies
        'cp.ReferencedAssemblies.Add("c:\yourProjectDir\bin\YourBaseClass.dll")
        'cp.ReferencedAssemblies.Add("YourBaseclass.dll")
        cp.CompilerOptions = "/t:library"
        cp.GenerateInMemory = True
        Dim sb As System.Text.StringBuilder = New System.Text.StringBuilder("")
        sb.Append("Imports System" & vbCrLf)
        sb.Append("Imports System.Xml" & vbCrLf)
        sb.Append("Imports System.Data" & vbCrLf)
        sb.Append("Imports System.Data.SqlClient" & vbCrLf)
        sb.Append("Imports Microsoft.VisualBasic" & vbCrLf)

        sb.Append("Namespace MyEvalNamespace  " & vbCrLf)
        sb.Append("Class MyEvalClass " & vbCrLf)

        sb.Append("public function  EvalCode() as Object " & vbCrLf)
        'sb.Append("YourNamespace.YourBaseClass thisObject = New YourNamespace.YourBaseClass()")
        sb.Append(vbCode & vbCrLf)
        sb.Append("End Function " & vbCrLf)
        sb.Append("End Class " & vbCrLf)
        sb.Append("End Namespace" & vbCrLf)
        Debug.WriteLine(sb.ToString()) ' look at this to debug your eval string
        Dim cr As System.CodeDom.Compiler.CompilerResults = icc.CompileAssemblyFromSource(cp, sb.ToString())
        Dim a As System.Reflection.Assembly = cr.CompiledAssembly
        Dim o As Object
        Dim mi As System.Reflection.MethodInfo
        o = a.CreateInstance("MyEvalNamespace.MyEvalClass")
        Dim t As Type = o.GetType()
        mi = t.GetMethod("EvalCode")
        Dim s As Object
        s = mi.Invoke(o, Nothing)
        Return s
    End Function


End Class ' EvalProvider


End Namespace

Answer 6

我不知道内置的 VB.net，但我们通过链接 IronPython 运行时并向其传递表达式来完成类似的操作。这比使用反射要快得多。