循环遍历 Excel 中某个范围的每一行

Question

这是我确信有一个内置函数的事情之一（而且我很可能在过去被告知过），但我正在挠头去记住它。

如何使用 Excel VBA 循环遍历多列范围的每一行？我一直在搜索的所有教程似乎都只提到在一维范围内工作......

Answer 1

Dim a As Range, b As Range

Set a = Selection

For Each b In a.Rows
    MsgBox b.Address
Next

Answer 2

像这样的东西：

Dim rng As Range
Dim row As Range
Dim cell As Range

Set rng = Range("A1:C2")

For Each row In rng.Rows
  For Each cell in row.Cells
    'Do Something
  Next cell
Next row

Answer 3

只是偶然发现了这一点，我想我会提出我的解决方案。我通常喜欢使用为多维数组分配范围的内置功能（我想这也是我的 JS 程序员）。

我经常编写这样的代码：

Sub arrayBuilder()

myarray = Range("A1:D4")

'unlike most VBA Arrays, this array doesn't need to be declared and will be automatically dimensioned

For i = 1 To UBound(myarray)

    For j = 1 To UBound(myarray, 2)

    Debug.Print (myarray(i, j))

    Next j

Next i

End Sub

为变量分配范围是在 VBA 中操作数据的一种非常强大的方法。

Answer 4

在循环中，我总是更喜欢使用 Cells 类，使用 R1C1 参考方法，如下所示：

Cells(rr, col).Formula = ...

这使我能够快速轻松地循环在范围<轻松地处理细胞：

Dim r As Long
Dim c As Long

c = GetTargetColumn() ' Or you could just set this manually, like: c = 1

With Sheet1 ' <-- You should always qualify a range with a sheet!

    For r = 1 To 10 ' Or 1 To (Ubound(MyListOfStuff) + 1)

        ' Here we're looping over all the cells in rows 1 to 10, in Column "c"
        .Cells(r, c).Value = MyListOfStuff(r)

        '---- or ----

        '...to easily copy from one place to another (even with an offset of rows and columns)
        .Cells(r, c).Value = Sheet2.Cells(r + 3, 17).Value


    Next r

End With