将 MDI 表单显示为模式

Question

这听起来违背了 MDI 的本质。有时我需要将 MDI 表单 (FormStyle=fsMdiChild) 显示为模式。我还需要访问另一个 MDI 表单的 Application.CreateForm 和 OnShow 事件之间的部分，即

Application.CreateForm(Form2,TForm2); // but don't set form2's visible property true.
Form2.caption:='not working example'; 
Form2.SomeMagicToSetVisibleTrue;

有什么想法吗？

Answer 1

对于第一个问题：添加另一个构造函数，例如 CreateAsMDI，如下所示：

constructor TModalAndMDIForm.CreateAsMDI(AOwner: TComponent); 
begin 
  f_blChild := true; 
  GlobalNameSpace.BeginWrite; 
  try 
    inherited CreateNew(AOwner); 
    if(not(csDesigning in ComponentState)) then begin 
      Include(FFormState, fsCreating); 
      try 
        FormStyle := fsMDIChild; 
        if(not(InitInheritedComponent(self, TForm))) then 
          raise Exception.CreateFmt('Can't create %s as MDI child', [ClassName]); 
      finally 
        Exclude(FFormState, fsCreating); 
      end; 
    end; 
  finally 
    GlobalNameSpace.EndWrite; 
  end; 
end; 

在普通构造函数中，只需将变量 f_blChild 设置为 false 并调用继承的 create。

您还需要两件事，而不是自我解释：

procedure TModalAndMDIForm.Loaded; 
begin 
  inherited; 
  if(f_blChild) then 
    Position := poDefault 
  else begin 
    Position := poOwnerFormCenter; 
    BorderStyle := bsDialog; 
  end; 
end; 
//----------------------------------------------------------------------------- 
procedure TModalAndMDIForm.DoClose(var Action: TCloseAction); 
begin 
  if(f_blChild) then 
    Action := caFree; 
  inherited DoClose(Action); 
end; 

现在您可以调用表单模式（如果使用标准构造函数创建），以及作为 MDI 子项（如果使用 CreateAsMDI 创建）。

如果您将其包含在表单声明中，

property IsChild: boolean read f_blChild; 

您甚至可以根据表单是否为 MDI 子表单执行操作，只需询问 isChild 属性即可。

至于你的第二个问题：不要使用Application.CreateForm，而是自己创建你的表单：

这里是模态和MDI的两个创建：

//Modal 
frmDialog := TMyForm.Create(self); 
// Your Code
frmDialog.ShowModal; 
frmDialog.Release; 

//MDI-Child 
frmDialog := TMyForm.CreateChild(self); 
// Your code
frmDialog.Show;

我已经将这个答案翻译成网站上的一篇文章DelphiPraxis。

Answer 2

最简单的方法是创建表单的一个简单子类，并

设置FormStyle = fsMDIChild

AND

Form.Visible = False

在属性检查器中 。这是经过尝试和测试的！

Answer 3

至少对于 Delphi 2007 和 2009，创建不可见的 MDI 子窗体很容易。对于早期的 Delphi 版本（无法在属性检查器中将 Visible 设置为 False），您只需为 OnCreate 提供一个处理程序> 事件并访问类的受保护字段：

procedure TMDIChild.FormCreate(Sender: TObject);
begin
  FFormState := FFormState - [fsVisible];
end;

这将禁用 MDI 子项的自动显示。完成其他初始化后，您只需Show它或将Visible设置为True即可。

我不会尝试回答您有关模式 MDI 子表单的问题，因为这违反了 Windows 平台的约定。

Answer 4

上面的答案实际上没有完成所需的工作。最佳答案也是错误的，原因如下：

• 打开第一个表格；
• 最大化它；
• 现在说这个表单调用另一个表单（mdi）；
• 当它以相同的方式构造时，您将得到有缺陷的布局...（它将 mdi 子级，但不会最大化，但第一个仍将最大化）。所以是一个有缺陷的状态。

如果您确实需要在运行时决定它是 fsMDIChild 还是 fsNormal，您需要应用以下方法。

1. 您的表单在设计中存储为 fsNormal（反之亦然）；
2. 重写InitializeNewForm方法；
3. 将FFormStyle的值设置为fsMDIChild（如下所示）。

...

TYourForm = class(TForm)
...
protected
  procedure InitializeNewForm; override;
...

procedure TYourForm.InitializeNewForm;
var
  FS: ^TFormStyle;
begin
  inherited;
  if DoYourCheckForMDI then
    begin
      FS := @FormStyle;
      FS^ := fsMDIChild;
    end;
end;