使用 awk 忽略转义分隔符（逗号）？

Question

如果我有一个带有转义逗号的字符串，如下所示：

a,b,{c\,d\,e},f,g

我如何使用 awk 将其解析为以下项目？

a
b
{c\,d\,e}
f
g

Answer 1

{
   split($0, a, /,/)
   j=1
   for(i=1; i<=length(a); ++i) {
      if(match(b[j], /\\$/)) {
         b[j]=b[j] "," a[i]
      } else {
         b[++j] = a[i]
      }
   }
   for(k=2; k<=length(b); ++k) {
      print b[k]
   }
}

1. 拆分为数组 a，使用 ',' 作为分隔符
2. 从 a 构建数组 b，合并以 结尾的行'\'
3. 打印数组 b （注意：从 2 开始，因为第一项为空）

此解决方案假定（目前）','是唯一用 '\' 转义的字符 - 也就是说，不需要处理输入中的任何 \\，也不需要处理诸如 < 之类的奇怪组合代码>\\\,\\,\\\\,,\,。

Answer 2

{
  gsub("\\\\,", "!Q!")
  n = split($0, a, ",")
  for (i = 1; i <= n; ++i) {
    gsub("!Q!", "\\,", a[i])
    print a[i]
  }
}

Answer 3

我不认为 awk 对这样的事情有任何内置支持。这里有一个解决方案，它不像 DigitalRoss 的那么短，但应该不会有意外碰到你的编弦的危险（！Q！）。由于它使用 if 进行测试，因此您还可以扩展它以小心字符串末尾是否确实有 \\,，这应该是转义斜杠, 不是逗号。

BEGIN {
    FS = ","
}

{
    curfield=1
    for (i=1; i<=NF; i++) {
        if (substr($i,length($i)) == "\\") {
            fields[curfield] = fields[curfield] substr($i,1,length($i)-1) FS
        } else {
            fields[curfield] = fields[curfield] $i
            curfield++
        }
    }
    nf = curfield - 1
    for (i=1; i<=nf; i++) {
        printf("%d: %s   ",i,fields[i])
    }
    printf("\n")
}