使用 Sqlite 数据填充 Tcl Treeview

Question

我正在构建一个读取 Sqlite Db 的 Tcl 应用程序。目前，我可以使用 Tcl 前端将数据输入数据库。现在，我试图弄清楚如何从 Tcl 前端显示 Sqlite Db 中的数据。

经过一些研究，我发现树视图小部件可以很好地满足我的需求。我现在有以下代码：

set z1 [ttk::treeview .c1.t1 -columns {1 2} -show headings]
$z1 heading #1 -text "First Name"
$z1 heading #2 -text "Last Name"

proc Srch {} {global z1
    sqlite3 db test.db
    pack $z1
    db close
}

当执行“Srch”过程（按钮事件）时，树视图 (z1) 出现，标题为名字和姓氏。此外，Sqlite Db 已连接，然后关闭。

我想添加代码，在连接到数据库和打包树视图（z1）之间从 Sqlite 数据库填充树视图。有谁知道使用 Sqlite 数据填充 Tcl 树视图的正确语法？

Answer 1

最好这样做：

proc Srch {} {
    global z1
    pack $z1
    foreach col {first last} name {First Last} {
        $z1 heading $col -text $name
    }
    sqlite3 db test.db
    db eval {SELECT first,last FROM t1} {
        $z1 insert {} end -values [list $first $last]
    }
    db close
}

这利用了 SQLite 与 Tcl 确实非常好的集成这一事实。

Answer 2

经过几个小时的反复试验，我终于弄清楚如何使用 sqlite 数据填充树视图小部件。不幸的是，我找不到任何网络资源，所以如果其他人遇到这个问题，答案如下：

set z1 [ttk::treeview .c1.t1 -columns {first last} -show headings]

proc Srch {} {
    global z1
    sqlite3 db test.db
    pack $z1
    set data [db eval {SELECT * FROM t1}]
    foreach col {first last} name {First Last} {
        .c1.t1 heading $col -text $name
    }
    foreach {first last} $data {
        .c1.t1 insert {} end -values [list $first $last]
    }
    db close
}

基本上，z1 是多列列表（树），Srch 是按钮驱动程序。执行时，树中将填充与每一列相对应的名字和姓氏。