找出 vim 中特定关键字/符号属于哪个突出显示组

Question

我从 TextMate 转到 Vim，我想自定义我的 vim 颜色方案。如果我能找出任何特定单词或符号属于哪个突出显示组，那将非常有帮助。在 TextMate 中，我会将插入符号放在有问题的单词/符号上，然后按 ctrl-shift-p，然后会出现一个工具提示，内容如下：

text.html.basic
meta.tag.structure.any.html
string.quoted.double.html

根据此信息，编辑要应用的 TextMate 颜色主题非常简单（或删除）格式化相关文本。

在 Vim 中，如果我想更改某个单词或符号的格式，我不知道从哪里开始。有没有相当于 TextMate 的 ctrl-shift-p 的东西？

Answer 1

我不确定我理解是否正确，但是您在寻找这个吗？

" adds to statusline
set laststatus=2
set statusline+=%{synIDattr(synID(line('.'),col('.'),1),'name')}

" a little more informative version of the above
nmap <Leader>sI :call <SID>SynStack()<CR>

function! <SID>SynStack()
    if !exists("*synstack")
        return
    endif
    echo map(synstack(line('.'), col('.')), 'synIDattr(v:val, "name")')
endfunc

Answer 2

获取有关突出显示的大量信息的另一种方法：

map <F3> :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">" . " FG:" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"fg#")<CR>

如果我将鼠标移动到 C 文件中的注释上并按 F3，我会得到：

hi<cCommentStart> trans<cCommentStart> lo<Comment> FG:#00ff00

这表明它位于突出显示组 cCommentStart，链接到 Comment 并以绿色显示 (#00ff00)。这是（修改）自此处，请参阅该页面以获取更多信息。

Answer 3

更新：来自 :help synID() （参见示例）：

synID({line}, {col}, {trans})                           *synID()*
                The result is a Number, which is the syntax ID at the position
                {line} and {col} in the current window.
                The syntax ID can be used with |synIDattr()| and
                |synIDtrans()| to obtain syntax information about text.
                {col} is 1 for the leftmost column, {line} is 1 for the first
                line.
                When {trans} is non-zero, transparent items are reduced to the
                item that they reveal.  This is useful when wanting to know
                the effective color.  When {trans} is zero, the transparent
                item is returned.  This is useful when wanting to know which
                syntax item is effective (e.g. inside parens).
                Warning: This function can be very slow.  Best speed is
                obtained by going through the file in forward direction.

                Example (echoes the name of the syntax item under the cursor):  
                        :echo synIDattr(synID(line("."), col("."), 1), "name")

据我所知，您能做的最好的是 :syntax，这将为您提供当前文件加载的所有语法的列表。我不知道有什么可以给出当前缓冲区的语法解析。

请注意，:syntax只是定义了语法项，它使用了:highlight 命令为语法项提供颜色。

一旦您决定要进行哪些更改，请将它们放入 ~/.vim/after/syntax/.vim 中。这些将在加载默认语法文件后应用您的更改。