当同一个 Perl 语句中有一个条件运算符和一个后缀条件时会发生什么？

Question

有人能解释一下这条线是如何工作的吗？

return $y < 0 ? - pip2 : pip2 if $x == 0;

如果 $y <0 它返回 -pip2，但是当 $y >= 0 和 $x 时它返回什么！ = 0 ？

这一行来自这个函数：

sub _atan {
    my( $y, $x ) = @_;

    return $y < 0 ? - pip2 : pip2 if $x == 0;
    return atan( $y / $x );
}

Answer 1

后缀“if”表示仅在条件为真时才执行 return 语句，因此

return $y < 0 ? - pip2 : pip2 if $x == 0;

与“如果您对 ?: 三元运算符感到困惑”相同

if ($x == 0)
{
    return $y < 0 ? - pip2 : pip2 ;
}

，也可以将其重写为常规 if 语句，以产生此结果

if ($x == 0)
{
    if ($y<0)
    {
        return -pip2;
    }
    else
    {
        return pip2;
    }
}

Answer 2

相同然后变为：

if($x == 0){
  if($y<0){
    return -pip2;
  }else{
    return pip2;
  }
}

它与整个函数

sub _atan {
  my( $y, $x ) = @_;
  if($x == 0){
    if($y<0){
      return -pip2;
    }else{
      return pip2;
    }
  }else{
    return atan( $y / $x );
  }
}

Answer 3

这是难以阅读的代码的一个很好的例子。

让我们比较一下重写代码示例的几种不同方法，看看我们在保持简洁性和提高可读性方面做得如何。

这个仅三元的版本在简洁性方面胜出，但仍然难以阅读：

sub _atan {
    my( $y, $x ) = @_;

    return $x == 0 ? ($y < 0  ? -pip2 : pip2)
                   : atan( $y / $x );  
}

我发现链式条件运算符 (?:) 仅当后续运算符落在 else 位置时才可读：

sub _atan {
    my( $y, $x ) = @_;

    return $x != 0 ? atan( $y / $x ) : 
           $y < 0  ? -pip2           : pip2;  
}

仍然简短，但可读性有所提高。

但是使用 if 和 unless 又如何呢？我们是否也可以使用它们来编写简洁、可读的代码？

从本质上来说，直接的 if/else 方法会更加冗长：

sub _atan {
    my( $y, $x ) = @_;

    my $atan;
    if( x == 0 ) {
        if( $y < 0 ) {
            $atan = -pip2;
        }
        else {
            $atan = pip2;
        }
    }
    else {
        $atan = atan( $y / $x )
    }            

    return $atan;  
}

很容易跟踪上面的内容并查看结果是什么。因此可读性获胜，但简洁性受到损害。

我发现使用 unless 和 if 的语句修饰符形式提供了一种向代码块添加短路逻辑的干净方法：

sub _atan {
    my( $y, $x ) = @_;

    return atan( $y / $x )
        unless $x == 0;

    return -pip2 if $y < 0;

    return pip2;  
}

这是简洁且可读的，但是在我看来，我们获得的回报似乎超出了我们的需要。

因此，如果我们在混合中引入条件运算符，我们会得到

sub _atan {
    my( $y, $x ) = @_;

    return atan( $y / $x )
        unless $x == 0;       

    return $y < 0  ? -pip2 : pip2;  
}

这种形式与上述任何一种形式一样简洁，但更容易理解：

sub _atan {
    my( $y, $x ) = @_;

    return atan( $y / $x )
        unless $x == 0;

    return $y < 0  ? -pip2 : pip2;  
}

嵌套的 if/else 子句可能很难理解。在构造决策代码时稍微小心一点可以大大提高可读性，从而提高可维护性，同时保留底层逻辑的简洁表达。

这里要修复的代码味道是条件运算符 (?:) 与语句修饰符形式 if 的巴洛克组合。通过重新安排测试的顺序并仔细选择如何表示条件逻辑，我们能够保持简洁并澄清代码。

Answer 4

用于解决问题的行太多会使代码难以维护（总是必须滚动）。嵌套 if 的解决方案要长 4 倍。想象一下使用小 4 倍的屏幕进行工作。我最喜欢的语法是：

sub _atan {
    my ($y, $x) = @_;
    return atan ($y / $x) if $x != 0;
    return $y < 0  ? -pip2 : pip2;
}

如果将后缀运算符放在下一行，那么使用后缀运算符的好处就会减少。
此行顺序（由 @daotoad 建议）允许将后缀条件放在更简单的行上。

初始语法也很好，但我不想处理包含以前帖子中建议的嵌套 if 的代码。