漂亮的打印 Excel 公式？

Question

有没有办法漂亮地打印Excel公式？

我有一些半复杂公式的工作表需要费力地完成，所以这会让我的生活变得更轻松一些。

我只是想将这样的东西变成

AC6+AD6+(IF(H6="Yes",1,IF(J6="Yes",1,0)))+IF(X6="Yes",1,0)

更具可读性的东西，而无需在 Vim 等中手动执行。 Excel 确实对括号进行了颜色匹配，但它仍然全部混合在一行上。

Answer 1

尝试使用 Excel 公式美化器 http://excelformulabeautifier.com/。它可以漂亮地打印（又名美化）Excel 公式。

（我帮助维护这一点，总是寻求反馈以使其变得更好。）

Answer 2

此 VBA 代码不会获奖，但可以快速查看典型公式。它只是执行您手动使用括号或分隔符执行的操作。将其粘贴到代码模块中并从 VBA 立即窗口命令行调用它。 （编辑：我最近不得不查看一些公式，并且我对原来答案的内容进行了改进，所以我回来并更改了它。）

Public Function ppf(f) As String
    Dim formulaStr As String

    If IsObject(f) Then
        Debug.Assert TypeOf f Is Range

        Dim rng As Range
        Set rng = f

        formulaStr = rng.Formula
    Else
        Debug.Assert VarType(f) = vbString

        formulaStr = f
    End If

    Dim tabs(0 To 99) As Long

    Dim tabNum As Long
    tabNum = 1

    Dim tabOffset As Long

    Dim i As Long
    Dim c As String
    For i = 1 To Len(formulaStr)
        c = Mid$(formulaStr, i, 1)

        If InStr("({", c) > 0 Then
            ppf = ppf & c

            tabNum = tabNum + 1
            tabs(tabNum) = tabs(tabNum - 1) + tabOffset + 1
            tabOffset = 0

            ppf = ppf & vbCrLf & Space(tabs(tabNum))
        ElseIf InStr(")}", c) > 0 Then
            tabNum = tabNum - 1
            tabOffset = 0

            ppf = ppf & c & vbCrLf & Space(tabs(tabNum))
        ElseIf InStr("+-*/^,;", c) > 0 Then
            tabOffset = 0

            ppf = ppf & c & vbCrLf & Space(tabs(tabNum))
        Else
            ppf = ppf & c

            tabOffset = tabOffset + 1
        End If
    Next i
End Function

如果你这样称呼它：

?ppf([q42])

你不必担心转义你的双引号等等。您将得到如下所示的输出：

AC6+
AD6+
(
 IF(
    H6="Yes",
    1,
    IF(
       J6="Yes",
       1,
       0)
    )
 )
+
IF(
   X6="Yes",
   1,
   0)

您还可以使用纯字符串调用它。

Answer 3

到 2023 年，迄今为止最简单的方法是安装微软自己的高级公式环境。除了漂亮的打印公式（然后可以将其复制粘贴到常规公式栏中）之外，它还具有许多其他功能。转到“插入”选项卡，“获取加载项”，搜索“Excel Labs”。

我还将衷心推荐“Formula Forge”插件作为评估公式的替代品。它使困难的公式更容易评估。

Answer 4

上述代码片段的这个版本现在也以不同的方式处理引用的字符，这意味着，它不会影响它们，如果它们位于字符串内部，则不会让它们影响缩进，例如：

"This ({)},;+*-/ won't lead to a linebreak" 

它由布尔变量 bInsideQuotes 控制。
它还用于

.FormulaLocal

使最终用户能够看到他们知道的东西。

Public Function prettyPrintFormula(f As Variant) As String
    Dim formulaStr As String
    Dim ppf As String

    If IsObject(f) Then
        Debug.Assert TypeOf f Is Range

        Dim rng As Range
        Set rng = f

        formulaStr = rng.FormulaLocal
    Else
        Debug.Assert VarType(f) = vbString

        formulaStr = f
    End If

    Dim tabs(0 To 99) As Long

    Dim tabNum As Long
    tabNum = 1

    Dim tabOffset As Long

    Dim i As Long
    Dim c As String
    Dim bInsideQuotes As Boolean
    bInsideQuotes = False
    For i = 1 To Len(formulaStr)
        c = Mid$(formulaStr, i, 1)

        If InStr("""", c) > 0 Then
            bInsideQuotes = Not bInsideQuotes
        End If
        If InStr("({", c) > 0 And Not bInsideQuotes Then
            ppf = ppf & c

            tabNum = tabNum + 1
            tabs(tabNum) = tabs(tabNum - 1) + tabOffset + 1
            tabOffset = 0

            ppf = ppf & vbCrLf & Space(tabs(tabNum))
        ElseIf InStr(")}", c) > 0 And Not bInsideQuotes Then
            tabNum = tabNum - 1
            tabOffset = 0

            ppf = ppf & c & vbCrLf & Space(tabs(tabNum))
        ElseIf InStr("+-*/^,;", c) > 0 And Not bInsideQuotes Then
            tabOffset = 0

            ppf = ppf & c & vbCrLf & Space(tabs(tabNum))
        Else
            ppf = ppf & c

            tabOffset = tabOffset + 1
        End If
    Next i
    prettyPrintFormula = ppf
End Function

Answer 5

我刚刚使用 VS Code sql-formatter 扩展。我只需将公式粘贴到 sql 文件并使用 sql 格式化程序进行格式化。

当我将其归档时，

{=IFERROR(INDEX(names,SMALL(IF(groups=$E5,ROW(names)-MIN(ROW(names))+1),COLUMNS($E$5:E5))),"")}

结果是这样的：

{ = IFERROR(
  INDEX(
    NAMES,
    SMALL(
      IF(groups = $ E5, ROW(NAMES) - MIN(ROW(NAMES)) + 1),
      COLUMNS($ E $ 5 :E5)
    )
  ),
  ""
) }

它并不完美，但符合我的口味。并且可以将其复制并重新使用到 Excel / google 表格中。